.SUBCKT NCV97200_BUCK VIN1 COMP1 VOUT1 SW1 GND1 DC1 PARAM: L1=3.0u RL1=40m
  
****SW 1 ****
R_R12         VOUT1 FB1  25k
R_R15         FB1 GND1  8k 
G_G1         GND1 CTRL1 V1 FB1 0.001
V_V1         V1 GND1 0.8
C_C2         GND1 CTRL1  13p 
R_esr	     COMP1 CTRL1 500
X_U1         VIN1 SW1 GND1 COMP1 DC1 HS LS PWMCM_L PARAM: L={L1} FS=2300000 RI=0.183 SE=476000
R_dson      HS SNS  1m
RSNS	    SNS GND1 183m
.model MBR1520	D(Is=4.091u Rs=4.683m Ikf=3.519 N=1 Xti=0 Eg=1.11 Cjo=2.216n
+		M=.4608 Vj=.75 Fc=.5 Isr=865.4u Nr=2)
D_LS         LS 0 MBR1520

.ENDS

********



.SUBCKT PWMCM_L a c p vc dc SW DIO param: L=4.7u Fs=200k Ri=1 Se=100m 
*
* This subckt is a current-mode DCM-CCM model including saturation voltages
*
Edc dcx 0 value = { v(d2)*v(cx,p)/(v(a,p)-v(cx,p)+1u) }
Xdc dcx dc limit param: clampH=0.99 clampL=7m
Ed2 d2X 0 value = { (2*{L}*{Fs}*I(VM)/(V(dc)*V(a,cx)+1u)) - V(dc) }
Xd2 d2X dc d2 limit2
GIap a p value = { (V(dc)/(V(dc)+V(d2)+1u))*I(VM) }
GIpc p cx value = { V(vc)/{Ri} }
GImju cx p value = { {Se}*V(dc)/({Ri}*{Fs}) + (v(cx,p)/{L})*V(d2)*{1/Fs}*(1-(V(dc)+V(d2))/2) }
Rdum1 dc 0 1Meg
Rdum2 vc 0 1Meg
Eloss cx cxx Value = { V(SW)*V(dc)+V(DIO)*V(d2) }
VM cxx c 
XC1 cxx p mode varicap
Emode mode 0 Value = { VALIF((2*{L}*{Fs}*I(VM)/(V(dc)*V(a,cx)+1u))
+ < 1, 1p , {4/((L)*(6.28*Fs)^2)}	) }
*
**** Loss generator ****
GSW 0 SW value = { I(VM) }
GID 0 DIO value = { I(VM) }
.ENDS


********
	.subckt limit d dc PARAM: clampH=0.88 clampL=16m
	Gd 0 dcx VALUE = { V(d)*100u }
	Rdc dcx 0 10k
	V1 clpn 0 {clampL}
	V2 clpp 0 {clampH}
	D1 clpn dcx dclamp
	D2 dcx clpp dclamp
	Edc dc 0 value={ V(dcx) }
	.model dclamp D Level=2  n=0.01 rs=100m
	.ENDS limit

	.subckt limit2 d2nc d d2c
	*
	Gd 0 d2cx d2nc 0 100u
	Rdc d2cx 0 10k
	V1 clpn 0 7m
	E2 clpp 0 Value = { 1-V(d)-6.687m }
	D1 clpn d2cx dclamp
	D2 d2cx clpp dclamp
	Edc d2c 0 value={ V(d2cx) }
	.model dclamp D Level=2  n=0.01 rs=100m
	.ENDS limit2

	.SUBCKT VARICAP 1 2 CTRL
	R1 1 3 1u
	VC 3 4
	EBC 4 2 Value = { (1/v(ctrl))*v(int) }
	GINT 0 INT Value = { I(VC) }
	CINT INT 0 1
	Rdum INT 0 10E10
	.ENDS 
*
********