*
*
.SUBCKT EFC4626R S1 G1 S2 G2
******************************************************************
**             On Discrete Modeling Group                       **
******************************************************************
**         (C) Copyright 2021 On Semiconductor Corporation      **
**                      All rights reserved                     **
**                                                              **
**                      EFC4626R Spice model                    **
**                   Revision RevA, 17 May 2021                 **
******************************************************************
X1 D1 G1 S1 EFC4626R_b
X2 D2 G2 S2 EFC4626R_b
RDrain D1 D2 5.0e-3
.ENDS EFC4626R


.SUBCKT EFC4626R_b  2 1 3      
*Nom Temp=25 deg C   
*25 Oct 99
Ca 12 8 1.5e-9
Cb 15 14 1.5e-9
Cin 6 8 5.7e-10

Dbody 7 5 DbodyMOD
Dbreak 5 11 DbreakMOD
Dplcap 10 5 DplcapMOD

Ebreak 11 7 17 18 28.5
Eds 14 8 5 8 1
Egs 13 8 6 8 1
Esg 6 10 6 8 1
Evthres 6 21 19 8 1
Evtemp 20 6 18 22 1

It 8 17 1

Lgate 1 9 5.53e-9
Ldrain 2 5 1e-9
Lsource 3 7 4.35e-9

RLgate 1 9 55.3
RLdrain 2 5 10
RLsource 3 7 43.5

Mmed 16 6 8 8 MmedMOD
Mstro 16 6 8 8 MstroMOD 
Mweak 16 21 8 8 MweakMOD
    
Rbreak 17 18 RbreakMOD 1
Rdrain 50 16 RdrainMOD 9.5e-3
Rgate 9 20 2.50
RSLC1 5 51 RSLCMOD 1e-6
RSLC2 5 50 1e3
Rsource 8 7 RsourceMOD 1.3e-3
Rvthres 22 8 RvthresMOD 1
Rvtemp 18 19 RvtempMOD 1

S1a 6 12 13 8 S1AMOD
S1b 13 12 13 8 S1BMOD
S2a 6 15 14 13 S2AMOD
S2b 13 15 14 13 S2BMOD

Vbat 22 19 DC 1

ESLC 51 50  VALUE={(V(5,51)/ABS(V(5,51)))*(PWR(V(5,51)/(1e-6*43.5),3.5))}


.MODEL DbodyMOD D (IS=2e-11 RS=36e-3 TRS1=2.1e-3 TRS2=2e-6 TT=6.30e-8 XTI=-3
+ CJO=2.0e-10 M=0.65)
.MODEL DbreakMOD D (RS=5.6e-1 TRS1=8e-4 TRS2=3e-6)
.MODEL DplcapMOD D (CJO=3e-10 IS=1e-30 M=0.85)
.MODEL MweakMOD NMOS (VTO=0.71 KP=0.8 IS=1e-30 N=10 TOX=1 L=1u W=1u RG=25.0) 
.MODEL MmedMOD NMOS (VTO=0.81 KP=18 IS=1e-30 N=10 TOX=1 L=1u W=1u RG=2.50)
.MODEL MstroMOD NMOS (VTO=0.9 KP=32 IS=1e-30 N=10 TOX=1 L=1u W=1u)


.MODEL RbreakMOD RES (TC1=1.05e-3 TC2=-5e-7)
.MODEL RdrainMOD RES (TC1=5e-3 TC2=1.5e-5)
.MODEL RSLCMOD RES (TC1=3.2E-3 TC2=3.0E-6)
.MODEL RsourceMOD RES (TC1=1e-3 TC2=1e-6)
.MODEL RvthresMOD RES (TC1=-1e-3 TC2=-1e-6)
.MODEL RvtempMOD RES (TC1=-0.01e-3 TC2=0)

.MODEL S1AMOD VSWITCH (RON=1e-5 ROFF=0.1 VON=-2.5 VOFF=-2)
.MODEL S1BMOD VSWITCH (RON=1e-5 ROFF=0.1 VON=-2 VOFF=-2.5)
.MODEL S2AMOD VSWITCH (RON=1e-5 ROFF=0.1 VON=-1.0 VOFF=0)
.MODEL S2BMOD VSWITCH (RON=1e-5 ROFF=0.1 VON=0 VOFF=-1.0)

.ENDS EFC4626R_b