.subckt PCP1403  2 1 3      
*Nom Temp=25 deg C    
*1-11-2021   

Ca 12  8 2.8e-10
Cb 15 14 2.8e-10
Cin 6 8 3.1e-10

Dbody 7 5 DbodyMOD
Dbreak 5 11 DbreakMOD
Dplcap 10 5 DplcapMOD

Ebreak 11 7 17 18 68
Eds 14 8 5 8 1
Egs 13 8 6 8 1
Esg 6 10 6 8 1
Evthres 6 21 19 8 1
Evtemp 20 6 18 22 1

It 8 17 1

Lgate 1 9 3.73e-9
Ldrain 2 5 1.00e-9
Lsource 3 7 3.43e-9

RLgate 1 9 37.3
RLdrain 2 5 10
RLsource 3 7 34.3

Mmed 16 6 8 8 MmedMOD
Mstro 16 6 8 8 MstroMOD 
Mweak 16 21 8 8 MweakMOD    


Rbreak 17 18 RbreakMOD 1
Rdrain 50 16 RdrainMOD 18.8e-3
Rgate 9 20 3.76
RSLC1 5 51 RSLCMOD 1e-6
RSLC2 5 50 1e3
Rsource 8 7 RsourceMOD 55e-3
Rvthres 22 8 RvthresMOD 1
Rvtemp 18 19 RvtempMOD 1
S1a 6 12 13 8 S1AMOD
S1b 13 12 13 8 S1BMOD
S2a 6 15 14 13 S2AMOD
S2b 13 15 14 13 S2BMOD

Vbat 22 19 DC 1

ESLC 51 50  VALUE={(V(5,51)/ABS(V(5,51)))*(PWR(V(5,51)/(1e-6*43),3))}

.MODEL DbodyMOD D (IS=8.0e-10 n=1.4 RS=18e-3 TRS1=2e-3 TRS2=0e-6
+ CJO=60e-12 TT=2.1e-8 M=0.4 XTI=3)
.MODEL DbreakMOD D (RS=3.70e-1 TRS1=9.10e-4 TRS2=-1e-6)
.MODEL DplcapMOD D (CJO=1.25e-10 IS=1e-30 N=10 M=0.55)

.MODEL MweakMOD NMOS (VTO=1.60 kp=0.08 IS=1e-30 N=10 TOX=1 L=1u W=1u RG=37.6 RS=.1) 
.MODEL MmedMOD NMOS (VTO=1.75 KP=1 IS=1e-30 N=10 TOX=1 L=1u W=1u RG=3.76)
.MODEL MstroMOD NMOS (VTO=2.05 KP=5.9 IS=1e-30 N=10 TOX=1 L=1u W=1u)
	

.MODEL RbreakMOD RES (TC1=1.13e-3 TC2=-3.00e-7)
.MODEL RdrainMOD RES (TC1=1e-3 TC2=1e-6)
.MODEL RSLCMOD RES (TC1=5.00e-3 TC2=5.05e-6)
.MODEL RsourceMOD RES (TC1=6.5e-3 TC2=20e-6)
.MODEL RvthresMOD RES (TC1=-2.48e-3 TC2=-8.30e-6)
.MODEL RvtempMOD RES (TC1=-2.6e-3 TC2=8.00e-7)

.MODEL S1AMOD VSWITCH (RON=1e-5 ROFF=0.1 VON=-8.00 VOFF=-6.80)
.MODEL S1BMOD VSWITCH (RON=1e-5 ROFF=0.1 VON=-6.80 VOFF=-8.00)
.MODEL S2AMOD VSWITCH (RON=1e-5 ROFF=0.1 VON=-0.50 VOFF=0.50)
.MODEL S2BMOD VSWITCH (RON=1e-5 ROFF=0.1 VON=0.50 VOFF=-0.50)

.ENDS PCP1403