.SUBCKT NTNS3C68NZ  2 1 3      
*Spice model for NTNS3C68NZ
*Nom Temp=25 deg C
*8 Jan 2021   

Ca 12 8  3e-10
Cb 15 14 3e-10
Cin 6 8 150e-12

Dbody 7 5 DbodyMOD
Dbreak 5 11 DbreakMOD
Dplcap 10 5 DplcapMOD

Ebreak 11 7 17 18 12.5
Eds 14 8 5 8 1
Egs 13 8 6 8 1
Esg 6 10 6 8 1
Evthres 6 21 19 8 1
Evtemp 20 6 18 22 1

It 8 17 1

Lgate 1 9 5.17e-9
Ldrain 2 5 1.0e-9
Lsource 3 7 2.33e-9

RLgate 1 9 51.7
RLdrain 2 5 10
RLsource 3 7 23.3

Mmed 16 6 8 8 MmedMOD
Mweak 16 21 8 8 MweakMOD    

Rbreak 17 18 RbreakMOD 1
Rdrain 50 16 RdrainMOD 39e-3
Rgate 9 20 0.88
RSLC1 5 51 RSLCMOD 1e-6
RSLC2 5 50 1e3
Rsource 8 7 RsourceMOD 20e-3
Rvthres 22 8 RvthresMOD 1
Rvtemp 18 19 RvtempMOD 1
S1a 6 12 13 8 S1AMOD
S1b 13 12 13 8 S1BMOD
S2a 6 15 14 13 S2AMOD
S2b 13 15 14 13 S2BMOD

Vbat 22 19 DC 1

ESLC 51 50  VALUE={(V(5,51)/ABS(V(5,51)))*(PWR(V(5,51)/(1e-6*250),3.5))}

.MODEL DbodyMOD D (IS=2.9e-13 XTI=0 RS=100e-3 TRS1=1.5e-3 TRS2=1.27e-6
+ CJO=18e-12 TT=4.90e-8 M=0.20)
.MODEL DbreakMOD D (RS=1.95e-1 TRS1=9.01e-4 TRS2=2.07e-6)
.MODEL DplcapMOD D (CJO=36e-12 M=0.65 IS=1e-30 RS=10m)

.MODEL MweakMOD NMOS (VTO=0.54 kp=0.05 IS=1e-30 N=10 TOX=1 L=1u W=1u RG=8.8 RS=.1) 
.MODEL MmedMOD NMOS (VTO=0.86 KP=4.4 IS=1e-30 N=10 TOX=1 L=1u W=1u RG=0.88)

.MODEL RbreakMOD RES (TC1=1.19e-3 TC2=-1.91e-7)
.MODEL RdrainMOD RES (TC1=2.9e-3 TC2=1.6e-5)
.MODEL RSLCMOD RES (TC1=9.92e-4 TC2=1.23e-6)
.MODEL RsourceMOD RES (TC1=0 TC2=0)
.MODEL RvthresMOD RES (TC1=-0.65e-3 TC2=-7.94e-6)
.MODEL RvtempMOD RES (TC1=-0.5e-3 TC2=1e-6)

.MODEL S1AMOD VSWITCH (RON=1e-5 ROFF=0.1 VON=-6 VOFF=-2.5)
.MODEL S1BMOD VSWITCH (RON=1e-5 ROFF=0.1 VON=-2.5 VOFF=-6)
.MODEL S2AMOD VSWITCH (RON=1e-5 ROFF=0.1 VON=-1.2 VOFF=0)
.MODEL S2BMOD VSWITCH (RON=1e-5 ROFF=0.1 VON=0 VOFF=-1.2)

.ENDS NTNS3C68NZ