*
****************************** IGBT Electrical Parameters ***************************
** Product: FGH30S130P
** 1300V, 30A Shorted-Anode IGBT
** Model Format: SIMetrix
**-----------------------------------------------------------------------------------
.SUBCKT FGH30S130P C G E
LE E 3 1.658e-9
LG G 2 1.183e-9
LC C 1 1.658e-9
Remit E 3 16.5
Rgate G 2 11.83
Rcoll C 1 16.58
M1 9 6 8 8 MSUB L=2E-06 W=6.804 
.MODEL MSUB NMOS 
+ LEVEL=7        VERSION=3.1      MOBMOD=3         CAPMOD=2 
+ PARAMCHK=1     NQSMOD=0         TOX=1E-07        XJ=1.4E-06 
+ NCH=1.3E+17    U0=582.1         VSAT=1E+05       DROUT=1 
+ DELTA=0.1      PSCBE2=0         RSH=0.001        VTH0=5.917 
+ VOFF=-0.1      NFACTOR=1.1      LINT=3E-07       CGSO=0 
+ CGSL=0         CGDO=0           CGBO=0           CGDL=0 
+ CJ=0           CF=0             CJSW=0           CKAPPA=0.2 
+ KT1=-1.985     KT2=0            UA1=5.691E-09    NJ=10 
RD 7 9 1E-06 
RS 4 8 0.01074 
CGC 6 1 1E-12 
CGE 6 4 1.05E-10
Q1 4 7 1 QSUB 
.model QSUB PNP 
+ IS=1.614E-18   BF=1             NF=1             VAF=1500 
+ IKF=1078       ISE=1.288E-14    NE=1.367         BR=0.85
+ NR=1           VAR=200          IKR=1000         ISC=1E-11 
+ NC=1           RB=0.2126        IRB=0.01872      RBM=7.087E-05 
+ RC=0.005822    XTB=1.431        XTI=1.4486       EG=1.1943
+ CJC=9.014E-11  VJC=0.51         MJC=0.52         CJE=5.294E-10 
+ VJE=0.46       MJE=0.9          TF=1.78E-07
RDS 7 4 1E+08 
RER 4 3 0.005344  TC=0.01932 
RG 6 2 1.5  TC=5.05e-3
RL 10 11 1 
D2 12 11 DCAP 
.model DCAP D 
+ IS=1E-32       N=50             BV=1430          IBV=0.001
+ CJO=5.21E-10   VJ=0.49          M=0.52           FC=0.5 
D3 0 11 DL 
.model DL D 
+ IS=1E-14       N=0.5   
VFI2 12 0 0 
FI2 6 7 VFI2 -1 
EV 10 0 7 6 1 
CAP 10 13 2.04E-08 
RCAP 10 14 1 
D4 0 14 DL 
VFI1 13 14 0 
FI1 6 7 VFI1 -1
DSAD E C SAD 
.MODEL SAD D 
+ IS=8.5E-10     RS=0.0254        EG=1.12          N=1.5 
+ TRS1=0.0025    TRS2=1.5E-05     TT=3.97E-07      BV=1430 
+ IBV=0.001    
.ENDS
****************************** IGBT Thermal Parameters ******************************
.SUBCKT FGH30S130P_Thermal_Foster TH TL
CTHERM1 TH 6 8.80e-3
CTHERM2 6 5  9.82e-3
CTHERM3 5 4  1.70e-2
CTHERM4 4 3  1.90e-2
CTHERM5 3 2  2.00e-2
CTHERM6 2 TL 8.40e-2
RTHERM1 TH 6 4.00e-4
RTHERM2 6 5  8.00e-3
RTHERM3 5 4  4.00e-2
RTHERM4 4 3  5.60e-2
RTHERM5 3 2  7.30e-2
RTHERM6 2 TL 1.02e-1
.ENDS FGH30S130P_Thermal_Foster
**-----------------------------------------------------------------------------------
.SUBCKT FGH30S130P_Thermal_Cauer TJ TCASE
C_Cthc1 TCASE TJ 1.07e-3 
C_Cthc2 TCASE 1 1.313e-3 
C_Cthc3 TCASE 2 1.48e-3 
C_Cthc4 TCASE 3 2.09e-3 
C_Cthc5 TCASE 4 5.29e-3 
C_Cthc6 TCASE 5 7.09e-3
R_Rthc1 TJ 1 2.00e-4
R_Rthc2 1 2  3.00e-3
R_Rthc3 2 3  4.50e-2
R_Rthc4 3 4  5.60e-2
R_Rthc5 4 5  7.30e-2
R_Rthc6 5 TCASE 1.02e-1
.ENDS FGH30S130P_Thermal_Cauer
**---------------------------------------------------------------------------------
** Creation: Sep.-17-2020   Rev.: 2.1
** ON Semiconductor
*