******************************************************************
**            ON Semiconductor Discrete Modeling Group          **
******************************************************************
**      Website: www.onsemi.com                                 **
******************************************************************
**       (C) Copyright 2013 ON Semiconductor Corporation        **
**                      All rights reserved                     **
**                                                              **
**                      FDPC8014S HSpice model                  **
**                    Revision RevA, 07 Nov 2017                **
******************************************************************
.SUBCKT FDPC8014S_Q1 2 1 3
.param tau=40 igain=85 fs=300
*Nom Temp 25 deg C
Dbreak 5 11 DbreakMOD
Lgate 1 9 0.517e-9
Ldrain 2 5 0.005e-9
Lsource 3 7 0.186e-9
RLgate 1 9 5.17
RLdrain 2 5 0.05
RLsource 3 7 1.86
Rgate 9 6 0.66
H1   161 141 V_H1 'tau'
V_H1 151 7 0V
V10  5 161 0
F1   7 161 V_F1 '-igain'
V_F1 171 141 0V
D3   151 161 Dbody_trr
.MODEL Dbody_trr D (IS=5e-12 n=1 RS=1.6e-3 TRS=2.5e-3
+ CJO=0.052e-9 M=0.35 TT=0 XTI=3)
R9   131 171  'tau*fs'
C2   161 131  1p
D1 100 5 D_SG_cap
D2 100 101 D_SG_cap
R1 101 7 0.41
C1 6 101 110e-12
.MODEL D_SG_cap D (IS=1e-9 n=1 RS=5e-3 CJO=1.85e-9 M=0.6 tref=25)
It 7 17 1
Ebreak 11 7 17 7 29.3
Rbreak 17 7 RbreakMOD 1
.MODEL RbreakMOD R (TC1=0.85e-3 TC2=0.1e-6)
.MODEL DbreakMOD D (RS=30e-3 TRS=1e-3)
Rsource 77 7 1.289e-3 
Rdrain 5 16 RdrainMOD 1.13e-3
.MODEL RdrainMOD R (TC1=7.3e-3 TC2=18e-6)
M_BSIM3 16 6 77 77 VDMOS W=3.329025 L=0.547e-6 NRS=0 NRD=0
.MODEL VDMOS NMOS (LEVEL=49 VERSION=3.1 MOBMOD=3 CAPMOD=2 paramchk=1 NQSMOD=0
+ TOX=309e-10
+ XJ=0.16e-6
+ NCH=2.33e17
+ U0=850 VSAT=500000 DROUT=1.2
+ DELTA=0.35 PSCBE2=0 RSH=0.289e-3
+ VTH0=0.33
+ VOFF=-0.1 NFACTOR=1.1
+ LINT=0.134e-6 DLC=0.134e-6
+ CGSO=150e-12 CGSL=0 CGDO=14.7e-12 CGDL=185e-12
+ CJ=0 CF=0 CKAPPA=0.25
+ KT1=-0.7 KT2=0 UA1=1.1e-9
+ NJ=10)
.ENDS FDPC8014S_Q1

.SUBCKT FDPC8014S_Q2 2 1 3
.param tau=40 igain=85 fs=300
*Nom Temp 25 deg C
Dbreak 5 11 DbreakMOD
Lgate 1 9 0.853e-9
Ldrain 2 5 0.004e-9
Lsource 3 7 0.178e-9
RLgate 1 9 8.53
RLdrain 2 5 0.04
RLsource 3 7 1.78
Rgate 9 6 0.36
H1   161 141 V_H1 'tau'
V_H1 151 7 0V
V10  5 161 0
F1   7 161 V_F1 '-igain'
V_F1 171 141 0V
D3   151 161 Dbody_trr
D4   151 161 DSchottky_trr
.MODEL Dbody_trr D (IS=45e-12 n=1 RS=2.7e-3 TRS=1.5e-3 
+ CJO=0.68e-9 M=0.37 TT=0 XTI=3)
.MODEL DSchottky_trr D (IS=3.5e-6 n=1.05 RS=90e-3 TRS=3e-3 
+ CJO=0.69e-9 M=0.37 TT=0 XTI=-17)
R9   131 171  'tau*fs'
C2   161 131  1p
D1 100 5 D_SG_cap
D2 100 101 D_SG_cap
R1 101 7 0.27
C1 6 101 488e-12
.MODEL D_SG_cap D (IS=1e-9 n=1 RS=5e-3 CJO=5.4e-9 M=0.545 tref=25)
It 7 17 1
Ebreak 11 7 17 7 30.55
Rbreak 17 7 RbreakMOD 1
.MODEL RbreakMOD R (TC1=0.8e-3 TC2=-1e-6)
.MODEL DbreakMOD D (RS=30e-3 TRS=1e-3)
Rsource 77 7 0.134e-3
Rdrain 5 16 RdrainMOD 0.55e-3
.MODEL RdrainMOD R (TC1=3.2e-3 TC2=5.6e-6)
M_BSIM3 16 6 77 77 VDMOS W=12.975 L=0.547e-6 NRS=0 NRD=0
.MODEL VDMOS NMOS (LEVEL=49 VERSION=3.1 MOBMOD=3 CAPMOD=2 paramchk=1 NQSMOD=0
+ TOX=309e-10
+ XJ=0.16e-6
+ NCH=2.74e17
+ U0=850 VSAT=500000 DROUT=1.2
+ DELTA=0.33 PSCBE2=0 RSH=0.134e-3
+ VTH0=0.08
+ VOFF=-0.1 NFACTOR=0.9
+ LINT=0.134e-6 DLC=0.134e-6
+ CGSO=150.4e-12 CGSL=0 CGDO=5e-12 CGDL=130e-12
+ CJ=0 CF=0 CKAPPA=0.85
+ KT1=-0.82 KT2=0 UA1=15e-9
+ NJ=10)
.ENDS FDPC8014S_Q2