.SUBCKT RFD16N05 2 1 3 ; REV 10/31/94
*Term. Conn.**** D G S
*Spice Model circuit file for the following parts:
* RFD16N05, RFD16N05SM
*************************************************************************
*   For further discussion of this PSPICE PowerFET macromodel consult   *
*    A New PSPICE Sub-circuit for the Power MOSFET Featuring Global     *
*     Temperature Options by William J. Hepp and C. Frank Wheatley      *
*NOM TEMP=25 deg C                                                      *
*************************************************************************
Ca 12 8 1.788e-10
Cb 15 14 1.875e-10
Cin 6 8 8.33e-10
Dbody 7 5 DBDMOD
Dbreak 5 11 DBKMOD
Dplcap 10 5 DPLCAPMOD
Ebreak 11 7 17 18 64.89
Eds 14 8 5 8 1
Egs 13 8 6 8 1
Esg 6 10 6 8 1
Escl 51 50 VALUE={(V(5,51)/ABS(V(5,51)))*(PWR(V(5,51)*1E6/94,7.0))}
Evto 20 6 18 8 1
It 8 17 1
Ldrain 2 5 1e-9
Lgate 1 9 4.56e-9
Lsource 3 7 4.13e-9
Mos1 16 6 8 8 MOSMOD M=0.99
Mos2 16 21 8 8 MOSMOD M=0.01
Rbreak 17 18 RBKMOD 1
Rdrain 5 16 RDSMOD 0.40e-3
Rgate 9 20 3.00
Rin 6 8 1e9
Rscl1 5 51 RSCLMOD 1e-6
Rscl2 5 50 1e3
Rsource 8 7 RDSMOD 21.5e-3
Rvto 18 19 RVTOMOD 1
S1a 6 12 13 8 S1AMOD
S1b 13 12 13 8 S1BMOD
S2a 6 15 14 13 S2AMOD
S2b 13 15 14 13 S2BMOD
Vbat 8 19 DC 1
Vto 21 6 0.82
.MODEL DBDMOD D (IS=2.50e-13 RS=7.10e-3 TRS1=3.04e-3 TRS2=-10.0e-6
+CJO=1.12e-9 TT=5.60e-8)
.MODEL DBKMOD D (RS=2.51e-1 TRS1=-6.57e-4 TRS2=1.66e-6)
.MODEL DPLCAPMOD D (CJO=6.10e-10 IS=1e-30 N=10)
.MODEL MOSMOD NMOS (VTO=3.96 KP=16.68 IS=1e-30 N=10 TOX=1 L=1u W=1u)
.MODEL RBKMOD RES (TC1=1.07e-3 TC2=-7.19e-7)
.MODEL RDSMOD RES (TC1=5.45e-3 TC2=1.66e-5)
.MODEL RSCLMOD RES (TC1=1.25e-3 TC2=17.0e-6)
.MODEL RVTOMOD RES (TC1=-5.15e-3 TC2=-4.83e-6)
.MODEL S1AMOD VSWITCH(RON=1e-5 ROFF=0.1 VON=-5.25 VOFF=-3.25)
.MODEL S1BMOD VSWITCH(RON=1e-5 ROFF=0.1 VON=-3.25 VOFF=-5.25)
.MODEL S2AMOD VSWITCH(RON=1e-5 ROFF=0.1 VON=0.56 VOFF=5.56)
.MODEL S2BMOD VSWITCH(RON=1e-5 ROFF=0.1 VON=5.56 VOFF=0.56)
.ENDS