.SUBCKT HUF76423P3  2 1 3      
*Nom Temp=25 deg C 
*7Sep99   

Ca 12 8 1.46e-9
Cb 15 14 1.46e-9
Cin 6 8 1.0e-9

Dbody 7 5 DbodyMOD
Dbreak 5 11 DbreakMOD
Dplcap 10 5 DplcapMOD

Ebreak 11 7 17 18 66.0
Eds 14 8 5 8 1
Egs 13 8 6 8 1
Esg 6 10 6 8 1
Evthres 6 21 19 8 1
Evtemp 20 6 18 22 1

It 8 17 1

Lgate 1 9 5.5e-9
Ldrain 2 5 1e-9
Lsource 3 7 4.4e-9

RLgate 1 9 55
RLdrain 2 5 10
RLsource 3 7 44

Mmed 16 6 8 8 MmedMOD
Mstro 16 6 8 8 MstroMOD 
Mweak 16 21 8 8 MweakMOD    

Rbreak 17 18 RbreakMOD 1
Rdrain 50 16 RdrainMOD 7.0e-3
Rgate 9 20 3.6
RSLC1 5 51 RSLCMOD 1e-6
RSLC2 5 50 1e3
Rsource 8 7 RsourceMOD 1.45e-2
Rvthres 22 8 RvthresMOD 1
Rvtemp 18 19 RvtempMOD 1
S1a 6 12 13 8 S1AMOD
S1b 13 12 13 8 S1BMOD
S2a 6 15 14 13 S2AMOD
S2b 13 15 14 13 S2BMOD

Vbat 22 19 DC 1

ESLC 51 50  VALUE={(V(5,51)/ABS(V(5,51)))*(PWR(V(5,51)/(1e-6*100),3.5))}

.MODEL DbodyMOD D (IS=6.3E-13 RS=6.8e-3 TRS1=1e-3 TRS2=1e-6 XTI=4.3
+ CJO=1.28e-9 TT=5.1e-8 M=0.5)
.MODEL DbreakMOD D (RS=2.9e-1 TRS1=1e-4 TRS2=0)
.MODEL DplcapMOD D (CJO=9.5e-10 IS=1e-30 N=10 M=.82)

.MODEL MmedMOD NMOS (VTO=2.1 KP=6 IS=1e-30 N=10 TOX=1 L=1u W=1u RG=3.6)
.MODEL MstroMOD NMOS (VTO=2.45 KP=60.5 IS=1e-30 N=10 TOX=1 L=1u W=1u)
.MODEL MweakMOD NMOS (VTO=1.79 kp=0.13 IS=1e-30 N=10 TOX=1 L=1u W=1u RG=36 RS=.1) 

.MODEL RbreakMOD RES (TC1=1.2e-3 TC2=-5e-7)
.MODEL RdrainMOD RES (TC1=1.3e-2 TC2=3.1e-5)
.MODEL RSLCMOD RES (TC1=5.5e-3 TC2=7e-6)
.MODEL RsourceMOD RES (TC1=1e-3 TC2=1e-6)
.MODEL RvthresMOD RES (TC1=-1.8e-3 TC2=-5.8e-6)
.MODEL RvtempMOD RES (TC1=-1.7e-3 TC2=8e-7)

.MODEL S1AMOD VSWITCH (RON=1e-5 ROFF=0.1 VON=-4.8 VOFF=-2.8)
.MODEL S1BMOD VSWITCH (RON=1e-5 ROFF=0.1 VON=-2.8 VOFF=-4.8)
.MODEL S2AMOD VSWITCH (RON=1e-5 ROFF=0.1 VON=-0.6 VOFF=.5)
.MODEL S2BMOD VSWITCH (RON=1e-5 ROFF=0.1 VON=.5 VOFF=-0.6)

.ENDS

*Thermal Model Subcircuit
.SUBCKT huf76423pt TH TL
*1Sep99

CTHERM1 TH c2 1.40e-3	   
CTHERM2 c2 c3 8.30e-3
CTHERM3 c3 c4 7.00e-3
CTHERM4 c4 c5 3.20e-3
CTHERM5 c5 c6 1.50e-2
CTHERM6 c6 TL 1.10

RTHERM1 TH c2 1.20e-2
RTHERM2 c2 c3 2.99e-2
RTHERM3 c3 c4 8.43e-2
RTHERM4 c4 c5 4.73e-1
RTHERM5 c5 c6 7.14e-1
RTHERM6 c6 TL 9.47e-2
.ENDS