.SUBCKT HUF75645  2 1 3      
*Nom Temp=25 deg C   
*21 May 99
Ca 12 8 5.31e-9
Cb 15 14 5.31e-9
Cin 6 8 3.56e-9

Dbody 7 5 DbodyMOD
Dbreak 5 11 DbreakMOD
Dplcap 10 5 DplcapMOD

Ebreak 11 7 17 18 115.5
Eds 14 8 5 8 1
Egs 13 8 6 8 1
Esg 6 10 6 8 1
Evthres 6 21 19 8 1
Evtemp 20 6 18 22 1

It 8 17 1

Lgate 1 9 5.1e-9
Ldrain 2 5 1.0e-9
Lsource 3 7 4.4e-9

RLgate 1 9 26
RLdrain 2 5 10
RLsource 3 7 11

Mmed 16 6 8 8 MmedMOD
Mstro 16 6 8 8 MstroMOD 
Mweak 16 21 8 8 MweakMOD
    
Rbreak 17 18 RbreakMOD 1
Rdrain 50 16 RdrainMOD 7.8e-3
Rgate 9 20 0.83
RSLC1 5 51 RSLCMOD 1e-6
RSLC2 5 50 1e3
Rsource 8 7 RsourceMOD 1.65e-3
Rvthres 22 8 RvthresMOD 1
Rvtemp 18 19 RvtempMOD 1

S1a 6 12 13 8 S1AMOD
S1b 13 12 13 8 S1BMOD
S2a 6 15 14 13 S2AMOD
S2b 13 15 14 13 S2BMOD

Vbat 22 19 DC 1

ESLC 51 50  VALUE={(V(5,51)/ABS(V(5,51)))*(PWR(V(5,51)/(1e-6*205),3.5))}

.MODEL DbodyMOD D (IS=3.00e-12 RS=1.78e-3 IKF=19 XTI=5 TRS1=2.25e-3 TRS2=1e-5 CJO=5.32e-9 TT=7.4e-8 M=0.68)
.MODEL DbreakMOD D (RS=2.15e-1 IKF=1 TRS1=8e-4 TRS2=3e-6)
.MODEL DplcapMOD D (CJO=5.55e-9 IS=1e-30 M=0.98)
.MODEL MmedMOD NMOS (VTO=3.13 KP=10 IS=1e-30 N=10 TOX=1 L=1u W=1u RG=0.83)
.MODEL MstroMOD NMOS (VTO=3.51 KP=93 IS=1e-30 N=10 TOX=1 L=1u W=1u)
.MODEL MweakMOD NMOS (VTO=2.65 KP=0.11 IS=1e-30 N=10 TOX=1 L=1u W=1u RG=8.33) 

.MODEL RbreakMOD RES (TC1=9.9e-4 TC2=-1.3e-6)
.MODEL RdrainMOD RES (TC1=9.40e-3 TC2=2.93e-5)
.MODEL RSLCMOD RES (TC1=2.63E-3 TC2=1.05E-6)
.MODEL RsourceMOD RES (TC1=1e-3 TC2=1e-6)
.MODEL RvthresMOD RES (TC1=-2.57e-3 TC2=-7.05e-6)
.MODEL RvtempMOD RES (TC1=-2.87e-3 TC2=-2.21e-6)

.MODEL S1AMOD VSWITCH (RON=1e-5 ROFF=0.1 VON=-6.2 VOFF=-2.4)
.MODEL S1BMOD VSWITCH (RON=1e-5 ROFF=0.1 VON=-2.4 VOFF=-6.2)
.MODEL S2AMOD VSWITCH (RON=1e-5 ROFF=0.1 VON=-1.8 VOFF=0.5)
.MODEL S2BMOD VSWITCH (RON=1e-5 ROFF=0.1 VON=0.5 VOFF=-1.8)

.ENDS

*Thermal Model Subcircuit
*HUF75645
*7/28/99
.SUBCKT huf75645t TH TL

CTHERM1 TH c2 8.8e-3	   
CTHERM2 c2 c3 2.5e-2
CTHERM3 c3 c4 2.7E-2
CTHERM4 c4 c5 3.7E-2
CTHERM5 c5 c6 4.4E-2
CTHERM6 c6 TL 3.4e-1

RTHERM1 TH c2 1.2E-2
RTHERM2 c2 c3 3.0e-2
RTHERM3 c3 c4 4.3e-2
RTHERM4 c4 c5 8.8e-2
RTHERM5 c5 c6 9.9e-2
RTHERM6 c6 TL 1.1e-1
.ENDS