.SUBCKT HUF75332P3  2 1 3
*Spice model for HUF75332P3, HUF75332G3 & HUF75332S3S   
*Nom Temp=25 deg C
* revised 17Feb99  

Ca 12 8 1.8e-9
Cb 15 14 1.73e-9
Cin 6 8 1.19e-9

Dbody 7 5 DbodyMOD
Dbreak 5 11 DbreakMOD
Dplcap 10 5 DplcapMOD

Ebreak 11 7 17 18 58.85
Eds 14 8 5 8 1
Egs 13 8 6 8 1
Esg 6 10 6 8 1
Evthres 6 21 19 8 1
Evtemp 20 6 18 22 1

It 8 17 1

Lgate 1 9 1e-9
Ldrain 2 5 1e-9
Lsource 3 7 1e-9
K1 Lsource Lgate 0.0085

RLgate 1 9 10
RLdrain 2 5 10
RLsource 3 7 10

Mmed 16 6 8 8 MmedMOD
Mstro 16 6 8 8 MstroMOD 
Mweak 16 21 8 8 MweakMOD
    
Rbreak 17 18 RbreakMOD 1
Rdrain 50 16 RdrainMOD 4.5e-3
RSLC1 5 51 RSLCMOD 1e-6
RSLC2 5 50 1e3
Rgate 9 20 1.3
Rsource 8 7 RsourceMOD 5.95e-3
Rvthres 22 8 RvthresMOD 1
Rvtemp 18 19 RvtempMOD 1

S1a 6 12 13 8 S1AMOD
S1b 13 12 13 8 S1BMOD
S2a 6 15 14 13 S2AMOD
S2b 13 15 14 13 S2BMOD

Vbat 22 19 DC 1

ESLC 51 50  VALUE={(V(5,51)/ABS(V(5,51)))*(PWR(V(5,51)/(1e-6*180),4.6))}

.MODEL DbodyMOD D (IS=1.3E-12 RS=3.0e-3 IKF=20 XTI=6 TRS1=2.7e-3 TRS2=7e-7 CJO=1.7e-9 TT=4.0e-8 M=0.45 vj=0.75)
.MODEL DbreakMOD D (RS=1.71e-2 IKF=1e-5 TRS1=-4e-4 TRS2=-1.55e-5)
.MODEL DplcapMOD D (CJO=1.8e-9 IS=1e-30 M=0.9 vj=1.45 )


.MODEL MmedMOD NMOS (VTO=3.183 KP=2 IS=1e-30 N=10 TOX=1 L=1u W=1u RG=1.3)
.MODEL MstroMOD NMOS (VTO=3.66 KP=51.5 IS=1e-30 N=10 TOX=1 L=1u W=1u)
.MODEL MweakMOD NMOS (VTO=2.703 KP=0.008 IS=1e-30 N=10 TOX=1 L=1u W=1u RG=13) 

.MODEL RbreakMOD RES (TC1=1.05e-3 TC2=4.5e-7)
.MODEL RdrainMOD RES (TC1=1.16e-2 TC2=1.7e-5)
.MODEL RSLCMOD RES (TC1=3.96e-3 TC2=2.7e-6)
.MODEL RsourceMOD RES (TC1=1e-3 TC2=1e-5)
.MODEL RvthresMOD RES (TC1=-2.8e-3 TC2=-1.0e-5)
.MODEL RvtempMOD RES (TC1=-2.75e-3 TC2= 5.0e-7)

.MODEL S1AMOD VSWITCH (RON=1e-5 ROFF=0.1 VON=-8 VOFF=-3)
.MODEL S1BMOD VSWITCH (RON=1e-5 ROFF=0.1 VON=-3 VOFF=-8)
.MODEL S2AMOD VSWITCH (RON=1e-5 ROFF=0.1 VON=0 VOFF=0.5)
.MODEL S2BMOD VSWITCH (RON=1e-5 ROFF=0.1 VON=0.5 VOFF=0)

.ENDS

*Thermal Model Subcircuit
*11Feb99
.SUBCKT HUF75332P3_thermal TH TL

CTHERM1 TH c2 4.00E-3	   
CTHERM2 c2 c3 7.00E-3
CTHERM3 c3 c4 7.50E-3
CTHERM4 c4 c5 8.00E-3
CTHERM5 c5 c6 1.85E-2
CTHERM6 c6 TL 12.55

RTHERM1 TH c2 7.09e-3
RTHERM2 c2 c3 1.77e-2
RTHERM3 c3 c4 4.97e-2
RTHERM4 c4 c5 2.79e-1
RTHERM5 c5 c6 4.21e-1
RTHERM6 c6 TL 5.58e-2
.ENDS