*FDS6982 at Temp. Electrical Model (Q1 N-Ch)
*--------------------------------------------------------
.SUBCKT FDS6982Q1 20 10 30 50
*20=DRAIN 10=GATE 30=SOURCE 50=VTEMP
Rg 10 11x 1
Rdu 12x 1 1u
M1 2 1 4x 4x DMOS L=1u W=1u
.MODEL DMOS NMOS(VTO=2 KP=30 
+THETA=0.1 VMAX=1.5E5 LEVEL=3)
Cgs 1 5x 750p
Rd 20 4 7.8E-3 
Dds 5x 4 DDS
.MODEL DDS D(M=2.94E-1 VJ=3.06E-2 CJO=478p)
Dbody 5x 20 DBODY
.MODEL DBODY D(IS=1E-14 N=0.817495 RS=.001867 TT=8.9n)
Ra 4 2 7.8E-3 
Rs 5x 5 0.5m
Ls 5 30 0.5n
M2 1 8 6 6 INTER
E2 8 6 4 1 2
.MODEL INTER NMOS(VTO=0 KP=10 LEVEL=1)
Cgdmax 7 4 620p
Rcgd 7 4 10meg
Dgd 6 4 DGD
Rdgd 6 4 10meg
.MODEL DGD D(M=2.94E-1 VJ=1.2E-2 CJO=620p)
M3 7 9 1 1 INTER
E3 9 1 4 1 -2
*ZX SECTION
EOUT 4x 6x poly(2) (1x,0) (3x,0) 0 0 0 0 1
FCOPY 0 3x VSENSE 1
RIN 1x 0 1G
VSENSE 6x 5x 0
RREF 3x 0 10m
*TEMP SECTION
ED 101 0 VALUE {V(50,100)}
VAMB 100 0 25
EKP 1x 0 101 0 .01
*VTO TEMP SECTION
EVTO 102 0 101 0 .001
EVT 12x 11x 102 0 1
*DIODE THEMO BREAKDOWN SECTION
EBL VB1 VB2 101 0 .08
VBLK VB2 0 30
D 20 DB1 DBLK
.MODEL DBLK D(IS=1E-14 CJO=.1p RS=.1)
EDB DB1 0 VB1 0 1
.ENDS FDS6982Q1
*----------------------------------------------------------
*FDS6982 at Temp. Electrical Model (Q2 N-Ch)
*----------------------------------------------------------
.SUBCKT FDS6982Q2 20 10 30 50
*20=DRAIN 10=GATE 30=SOURCE 50=VTEMP
Rg 10 11x 1
Rdu 12x 1 1u
M1 2 1 4x 4x DMOS L=1u W=1u
.MODEL DMOS NMOS(VTO=2.6 KP=70
+THETA=.08 VMAX=1E5 LEVEL=3)
Cgs 1 5x 1780p
Rd 20 4 4E-3 
Dds 5x 4 DDS
.MODEL DDS D(M=4.63E-1 VJ=9.44E-1 CJO=1008p)
Dbody 5x 20 DBODY
.MODEL DBODY D(IS=1.88E-12 N=1.026451 RS=.000504 TT=12.4n)
Ra 4 2 4E-3 
Rs 5x 5 0.5m
Ls 5 30 0.5n
M2 1 8 6 6 INTER
E2 8 6 4 1 2
.MODEL INTER NMOS(VTO=0 KP=10 LEVEL=1)
Cgdmax 7 4 1440p
Rcgd 7 4 10meg
Dgd 6 4 DGD
Rdgd 6 4 10meg
.MODEL DGD D(M=1.92E-1 VJ=1.55E-3 CJO=1440p)
M3 7 9 1 1 INTER
E3 9 1 4 1 -2
*ZX SECTION
EOUT 4x 6x poly(2) (1x,0) (3x,0) 0 0 0 0 1
FCOPY 0 3x VSENSE 1
RIN 1x 0 1G
VSENSE 6x 5x 0
RREF 3x 0 10m
*TEMP SECTION
ED 101 0 VALUE {V(50,100)}
VAMB 100 0 25
EKP 1x 0 101 0 .006
*VTO TEMP SECTION
EVTO 102 0 101 0 .0012
EVT 12x 11x 102 0 1
*DIODE THEMO BREAKDOWN SECTION
EBL VB1 VB2 101 0 .08
VBLK VB2 0 30
D 20 DB1 DBLK
.MODEL DBLK D(IS=1E-14 CJO=.1p RS=.1)
EDB DB1 0 VB1 0 1
.ENDS FDS6982Q2
*FDS6982 (Rev.A) 6/23/04 **ST