*FDS4501H at Electrical Model (Complementary N-Ch)
*---------------------------------------------------------
.SUBCKT FDS4501HN 20 10 30 50
*20=DRAIN 10=GATE 30=SOURCE 50=VTEMP
Rg 10 11x 1
Rdu 12x 1 1u
M1 2 1 4x 4x DMOS L=1u W=1u
.MODEL DMOS NMOS(VTO=2 KP=8.14E+1
+THETA=.1 VMAX=1E5 LEVEL=3)
Cgs 1 5x 1570p
Rd 20 4 6E-3 
Dds 5x 4 DDS
.MODEL DDS D(M=4.41E-1 VJ=8.4E-1 CJO=710p)
Dbody 5x 20 DBODY
.MODEL DBODY D(IS=4.44E-11 N=1.169953 RS=.000215 TT=10.73n)
Ra 4 2 6E-3 
Rs 5x 5 0.5m
Ls 5 30 0.5n
M2 1 8 6 6 INTER
E2 8 6 4 1 2
.MODEL INTER NMOS(VTO=0 KP=10 LEVEL=1)
Cgdmax 7 4 1181p
Rcgd 7 4 10meg
Dgd 6 4 DGD
Rdgd 6 4 10meg
.MODEL DGD D(M=2.88E-1 VJ=1.02E-2 CJO=1181p)
M3 7 9 1 1 INTER
E3 9 1 4 1 -2
*ZX SECTION
EOUT 4x 6x poly(2) (1x,0) (3x,0) 0 0 0 0 1
FCOPY 0 3x VSENSE 1
RIN 1x 0 1G
VSENSE 6x 5x 0
RREF 3x 0 10m
*TEMP SECTION
ED 101 0 VALUE {V(50,100)}
VAMB 100 0 25
EKP 1x 0 101 0 .005
*VTO TEMP SECTION
EVTO 102 0 101 0 .001
EVT 12x 11x 102 0 1
*DIODE THEMO BREAKDOWN SECTION
EBL VB1 VB2 101 0 .08
VBLK VB2 0 30
D 20 DB1 DBLK
.MODEL DBLK D(IS=1E-14 CJO=.1p RS=.1)
EDB DB1 0 VB1 0 1
.ENDS FDS4501HN
*---------------------------------------------------------
*FDS4501H at Electrical Model (Complementary P-Ch)
*---------------------------------------------------------
.SUBCKT FDS4501HP 20 10 30 50
*20=DRAIN 10=GATE 30=SOURCE 50=VTEMP
Rg 10 11x 1
Rdu 12x 1 1u
M1 2 1 4x 4x DMOS L=1u W=1u
.MODEL DMOS PMOS(VTO=-0.87 KP=2.5E+1
+THETA=0.25 VMAX=8.5E5 LEVEL=3)
Cgs 1 5x 1300p
Rd 20 4 7E-3 
Dds 4 5x DDS
.MODEL DDS D(M=4.26E-1 VJ=3.39E-1 CJO=562p)
Dbody 20 5x DBODY
.MODEL DBODY D(IS=3.81E-10 N=1.145283 RS=0.00084 TT=10.26n)
Ra 4 2 7E-3 
Rs 5x 5 0.5m
Ls 5 30 0.5n
M2 1 8 6 6 INTER
E2 8 6 4 1 2
.MODEL INTER PMOS(VTO=0 KP=10 LEVEL=1)
Cgdmax 7 4 1050p
Rcgd 7 4 10meg
Dgd 4 6 DGD
Rdgd 4 6 10meg
.MODEL DGD D(M=3.2E-1 VJ=4.23E-3 CJO=1050p)
M3 7 9 1 1 INTER
E3 9 1 4 1 -2
*ZX SECTION
EOUT 4x 6x poly(2) (1x,0) (3x,0) 0 0 0 0 1
FCOPY 0 3x VSENSE 1
RIN 1x 0 1G
VSENSE 6x 5x 0
RREF 3x 0 10m
*TEMP SECTION
ED 101 0 VALUE {V(50,100)}
VAMB 100 0 25
EKP 1x 0 101 0 .012
*VTO SECTION
EVTO 102 0 101 0 .0007
EVT 11x 12x 102 0 1
*DIODE THERMO BREAKDOWN SECTION
EBL VB1 VB2 101 0  0.8
VBLK VB2 0 20
D DB1 20 DBLK
.MODEL DBLK D(IS=1E-14 CJO=.1p RS=.1)
EDB 0 DB1 VB1 0 1
.ENDS FDS4501HP
*
*FDS4501H  5/17/02 (Rev.A1) **ST