.SUBCKT FDS2572 2 1 3
*Spice model for FDS2572
*Nom Temp=25 deg C 
*7/20/01

Ca 12 8 8e-10
Cb 15 14 8e-10
Cin 6 8 2e-9

Dbody 7 5 DbodyMOD
Dbreak 5 11 DbreakMOD
Dplcap 10 5 DplcapMOD

Ebreak 11 7 17 18 157.4
Eds 14 8 5 8 1
Egs 13 8 6 8 1
Esg 6 10 6 8 1
Evthres 6 21 19 8 1
Evtemp 20 6 18 22 1

It 8 17 1

Lgate 1 9 5.61e-9
Ldrain 2 5 1.0e-9
Lsource 3 7 1.98e-9

RLgate 1 9 56.1
RLdrain 2 5 10
RLsource 3 7 19.8

Mstro 16 6 8 8 MstroMOD 
Mmed 16 6 8 8 MmedMOD
Mweak 16 21 8 8 MweakMOD

Rbreak 17 18 RbreakMOD 1
Rdrain 50 16 RdrainMOD 2.1e-2
Rgate 9 20 1.47
RSLC1 5 51 RSLCMOD 1e-6
RSLC2 5 50 1e3
Rsource 8 7 RsourceMOD 1.5e-2
Rvthres 22 8 RvthresMOD 1
Rvtemp 18 19 RvtempMOD 1
S1a 6 12 13 8 S1AMOD
S1b 13 12 13 8 S1BMOD
S2a 6 15 14 13 S2AMOD
S2b 13 15 14 13 S2BMOD

Vbat 22 19 DC 1

ESLC 51 50  VALUE={(V(5,51)/ABS(V(5,51)))*(PWR(V(5,51)/(1e-6*65),3))}

.MODEL DbodyMOD D (IS=4e-11 N=1.131 RS=4.4e-3 TRS1=2e-3 TRS2=1e-6
+ CJO=1.44e-9 M=0.67 TT=7.4e-8 XTI=4.2)
.MODEL DbreakMOD D (RS=0.38 TRS1=2e-3 TRS2=-8.9e-6)
.MODEL DplcapMOD D (CJO=5e-10 IS=1e-30 N=10 M=0.7)

.MODEL MstroMOD NMOS (VTO=4.05 KP=85 IS=1e-30 N=10 TOX=1 L=1u W=1u)
.MODEL MmedMOD NMOS (VTO=3.35 KP=5 IS=1e-30 N=10 TOX=1 L=1u W=1u RG=1.47)
.MODEL MweakMOD NMOS (VTO=2.76 KP=0.05 IS=1e-30 N=10 TOX=1 L=1u W=1u RG=14.7 RS=0.1)

.MODEL RbreakMOD RES (TC1=1.1e-3 TC2=-3e-7)
.MODEL RdrainMOD RES (TC1=1e-2 TC2=3e-5)
.MODEL RSLCMOD RES (TC1=3e-3 TC2=1e-6)
.MODEL RsourceMOD RES (TC1=4.5e-3 TC2=1e-6)
.MODEL RvtempMOD RES (TC1=-5e-3 TC2=2e-6)
.MODEL RvthresMOD RES (TC1=-3e-3 TC2=-1.4e-5)

.MODEL S1AMOD VSWITCH (RON=1e-5 ROFF=0.1 VON=-10 VOFF=-2)
.MODEL S1BMOD VSWITCH (RON=1e-5 ROFF=0.1 VON=-2 VOFF=-10)
.MODEL S2AMOD VSWITCH (RON=1e-5 ROFF=0.1 VON=-0.8 VOFF=0.3)
.MODEL S2BMOD VSWITCH (RON=1e-5 ROFF=0.1 VON=0.3 VOFF=-0.8)
.ENDS

.SUBCKT FDS2572_thermal TH TL
*Thermal Model Subcircuit
*8/17/01 Area = 1 sqr inch

CTHERM1 TH 8 2.0e-3
CTHERM2 8 7 5.0e-3
CTHERM3 7 6 1.0e-2
CTHERM4 6 5 4.0e-2
CTHERM5 5 4 9.0e-2
CTHERM6 4 3 2e-1
CTHERM7 3 2 1
CTHERM8 2 TL 3

RTHERM1 TH 8 1e-1
RTHERM2 8 7 5e-1
RTHERM3 7 6 1
RTHERM4 6 5 5
RTHERM5 5 4 8
RTHERM6 4 3 12
RTHERM7 3 2 18
RTHERM8 2 TL 25

.ends