* PSpice Model Editor - Version 10.5.0
*$
.SUBCKT FDMS8690 2 1 3    
*Nom Temp=25 deg C
Dbody 7 5 DbodyMOD
Dbreak 5 11 DbreakMOD
Lgate 1 9 1.5e-9
Ldrain 2 5 1.0e-9
Lsource 3 7 0.15e-9
RLgate 1 9 15
RLdrain 2 5 10
RLsource 3 7 1.5
Rgate 9 6 1.5
It 7 17 1
Ebreak 11 7 17 7 33
Rbreak 17 7 RbreakMOD 1
.MODEL RbreakMOD RES (TC1=8e-4 TC2=-1e-6)
.MODEL DbodyMOD D (IS=5.26e-12 n=1.03 RS=3.6e-3 TRS1=1.5e-3 TRS2=0 
+ CJO=1e-9 M=0.3 TT=1e-10 XTI=1)
.MODEL DbreakMOD D (RS=8e-2 TRS1=1e-3 TRS2=0)
Rdrain 5 16 RdrainMOD 4.4e-3
.MODEL RdrainMOD RES (TC1=3.5e-3 TC2=3.2e-6)
M_BSIM3 16 6 7 7 Bsim3 W=2.303 L=0.8e-6 NRS=1 NRD=0
.MODEL Bsim3 NMOS (LEVEL=7 VERSION=3.1 MOBMOD=3 CAPMOD=2 paramchk=1 NQSMOD=0)
**Process Parameters
+ TOX=400e-10 ;Oxide thickness
+ XJ=0.73e-6 ;Channel depth
+ NCH=1.4e17 ;Channel concentration
**Channel Current
+ U0=750 VSAT=5e5 DROUT=1.2
+ DELTA=0.1 PSCBE2=1e-5 RSH=2.3e-3   
**Threshold voltage
+ VTH0=1.5
**Sub-threshold characteristics
+ VOFF=-.1 NFACTOR=2
**Junction diodes and Capacitance
+ LINT=0.12e-6 DLC=0.12e-6 
+ CGSO=100e-12 CGSL=0 CGDO=18e-12 CGDL=130e-12
+ CJ=0 CF=0 CKAPPA=1 
**Temperature parameters
+ KT1=-1.1 KT2=0 UA1=0.8e-8 
+ NJ=10)
.ENDS
*FDMS8690 (Rev.B) 6/12/2007
*ST
*$