.SUBCKT FDMS8680 2 1 3    
*Nom Temp=25 deg C
Dbody 7 5 DbodyMOD
Dbreak 5 11 DbreakMOD
Ebreak 11 7 17 7 33
Lgate 1 9 2.185e-9
Ldrain 2 5 0.1e-9
Lsource 3 7 0.319e-9
RLgate 1 9 21.85
RLdrain 2 5 1
RLsource 3 7 3.19
Rgate 9 6 0.8
It 7 17 1
Rbreak 17 7 RbreakMOD 1
.MODEL RbreakMOD RES (TC1=0.8e-3 TC2=-1e-6)
.MODEL DbodyMOD D (IS=1.6e-12 n=1 RS=1.81E-3 TRS1=1.2e-3 TRS2=1e-6
+ CJO=1.2e-9 M=0.31 TT=1e-10 XTI=3)
.MODEL DbreakMOD D (RS=8e-3 TRS1=1e-3 TRS2=0)
Rdrain 5 16 RdrainMOD 2.65e-3
.MODEL RdrainMOD RES (TC1=8.1e-3 TC2=3.2e-6)
M_BSIM3 16 6 7 7 Bsim3 W=2.3 L=0.8e-6 NRS=1 NRD=0
.MODEL Bsim3 NMOS (LEVEL=7 VERSION=3.1 MOBMOD=3 CAPMOD=2 paramchk=1 NQSMOD=0
*Process Parameters
+ TOX=450e-10 ;Oxide thickness
+ XJ=0.76u ;Channel depth
+ NCH=1.75e17 ;Channel concentration
*Channel Current
+ U0=700 VSAT=2e5 DROUT=0.9
+ DELTA=0.1 PSCBE2=1e-5 RSH=0.78e-3   
*Threshold voltage
+ VTH0=1.9
*Sub-threshold characteristics
+ VOFF=-0.5 NFACTOR=1.1
*Junction diodes and Capacitance
+ LINT=0.11e-6 DLC=0.11e-6 
+ CGSO=90e-12 CGSL=0 CGDO=18e-12 CGDL=140e-12
+ CJ=0 CF=0 CKAPPA=1.2
* Temperature parameters
+ KT1=-1.05 KT2=0 UA1=3.8e-9
+ NJ=10)
*FDMS8680(Rev.A) 8/10/2007
*ST
.ENDS

.SUBCKT FDMS8680_Thermal_min_pad TH TL
*Thermal Model Subcircuit  16 July 2008
CTHERM1 th c2 2.0E-03   
CTHERM2 c2 c3 1.4E-02   
CTHERM3 c3 c4 0.6E-01   
CTHERM4 c4 c5 1.7E-01   
CTHERM5 c5 c6 0.8E+00   
CTHERM6 c6 tl 2.8   

RTHERM1 th c2 0.8
RTHERM2 c2 c3 1.5
RTHERM3 c3 c4 7.9
RTHERM4 c4 c5 26
RTHERM5 c5 c6 35
RTHERM6 c6 tl 39
.ends FDMS8680_Thermal_min_pad