* PSpice Model Editor - Version 10.5.0
*$
.SUBCKT FDMS8674 2 1 3    
*Nom Temp=25 deg C
Dbody 7 5 DbodyMOD
Dbreak 5 11 DbreakMOD
Lgate 1 9 2.185e-9
Ldrain 2 5 0.004e-9
Lsource 3 7 0.533e-9
RLgate 1 9 21.85
RLdrain 2 5 0.04
RLsource 3 7 5.33
Rgate 9 6 0.9
It 7 17 1
Ebreak 11 7 17 7 33
Rbreak 17 7 RbreakMOD 1
.MODEL RbreakMOD RES (TC1=0.8e-3 TC2=-1e-6)
.MODEL DbodyMOD D (IS=4.25e-12 n=1 RS=2.85e-3 TRS1=3.5e-3 TRS2=0
+ CJO=1.68e-9 M=0.3 TT=0.1e-9 XTI=-1.5)
.MODEL DbreakMOD D (RS=70e-3 TRS1=1e-3 TRS2=0)
Rdrain 5 16 RdrainMOD 2.55e-3
.MODEL RdrainMOD RES (TC1=5.7e-3 TC2=3.2e-6)
M_BSIM3 16 6 7 7 Bsim3 W=3.57 L=0.81e-6 NRS=1 NRD=0
.MODEL  Bsim3 NMOS (LEVEL=7 VERSION=3.1 MOBMOD=3 CAPMOD=2 paramchk=1 NQSMOD=0)
**Process Parameters
+ TOX=450e-10 ;Oxide thickness
+ XJ=0.58u ;Channel depth
+ NCH=1.6e17 ;Channel concentration
**Channel Current
+ U0=700 VSAT=5e5 DROUT=1.2
+ DELTA=0.1 PSCBE2=1e-5 RSH=0.866e-3   
**Threshold voltage
+ VTH0=1.75
**Sub-threshold characteristics
+ VOFF=-.1 NFACTOR=1.1
**Junction diodes and Capacitance
+ LINT=0.12u DLC=0.12u 
+ CGSO=95p CGSL=0 CGDO=8p CGDL=115p
+ CJ=0 CF=0 CKAPPA=2.2
** Temperature parameters
+ KT1=-1.1 KT2=0 UA1=2.2e-9
+ NJ=10)
.ENDS
*FDMS8674(Rev.A1) 1/16/2008
*ST
*$