* PSpice Model Editor - Version 10.5.0
*$
.SUBCKT FDMS8670S 2 1 3    
*Nom Temp=25 deg C
Dbody 7 5 DbodyMOD
Dbreak 5 11 DbreakMOD
Lgate 1 9 2.34e-9
Ldrain 2 5 1e-9
Lsource 3 7 0.0689e-9
RLgate 1 9 23.4
RLdrain 2 5 10
RLsource 3 7 0.69
Rgate 9 6 1.4
It 7 17 1
Ebreak 11 7 17 7 33
Rbreak 17 7 RbreakMOD 1
.MODEL RbreakMOD RES (TC1=9e-4 TC2=-1e-6)
.MODEL DbodyMOD D (IS=1.45e-5 n=1.06 RS=1.5e-2 TRS1=2.5e-3 TRS2=1e-6 
+ CJO=2.2e-9 M=0.5 TT=1e-10 XTI=-23
.MODEL DbreakMOD D (RS=9.5e-2 TRS1=1e-3 TRS2=1E-6)
Rdrain 5 16 RdrainMOD  1.92e-3
.MODEL RdrainMOD RES (TC1=2e-3 TC2=3e-5)
M_BSIM3 16 6 7 7 Bsim3 W=5.7 L=0.9e-6 NRS=1 NRD=0
.MODEL  Bsim3 NMOS (LEVEL=7 VERSION=3.1 MOBMOD=3 CAPMOD=2 paramchk=1 NQSMOD=0)
**Process Parameters
+ TOX=400e-10 ;Oxide thickness
+ XJ=0.97e-6 ;Channel depth
+ NCH=2.15e17 ;Channel concentration
**Channel Current
+ U0=700 VSAT=5e5 DROUT=3.5
+ DELTA=0.15 PSCBE2=1e-5 RSH=0.5e-3   
**Threshold voltage
+ VTH0=1.25
**Sub-threshold characteristics
+ VOFF=-.1 NFACTOR=1.5
**Junction diodes and Capacitance
+ LINT=0.165e-6 DLC=0.165e-6 
+ CGSO=85e-12 CGSL=0 CGDO=20e-12 CGDL=220e-12
+ CJ=0 CF=0 CKAPPA=1.3
** Temperature parameters
+ KT1=-1.1 KT2=0 UA1=0.6e-8 
+ NJ=10)
.ENDS
*FDMS8670S (Rev.B) 6/11/2007
*ST
*$