.SUBCKT FDMS8660AS 2 1 3
*Nom Temp 25 deg C
Dbody 7 5 DbodyMOD
Dschottky 7 5 DSchottkyMOD
Dbreak 5 11 DbreakMOD
Lgate 1 9 2.185e-9
Ldrain 2 5 0.004e-9
Lsource 3 7 1e-9
RLgate 1 9 21.85
RLdrain 2 5 0.04
RLsource 3 7 10
Rgate 9 6 1.2
It 7 17 1
Ebreak 11 7 17 7 35.8
Rbreak 17 7 RbreakMOD 1
.MODEL RbreakMOD RES (TC1=1.3e-3 TC2=-1e-6)
.MODEL DbodyMOD D (IS=2e-12 n=1 RS=0.8e-3 TRS1=1.5e-3 TRS2=1e-6
+ CJO=2e-9 M=0.3 TT=0.1e-9 XTI=1)
.MODEL DSchottkyMOD D (IS=1.1e-5 n=1 RS=13e-3 TRS1=1.5e-3 TRS2=1e-6
+ CJO=4e-9 M=0.45 TT=0.0013e-9 XTI=-20)
.MODEL DbreakMOD D (RS=70e-3 TRS1=1e-3 TRS2=1e-6)
Rsource 7a 7 0.25e-3
Rdrain 5 16 RdrainMOD 1.025e-3
.MODEL RdrainMOD RES (TC1=5.0e-3 TC2=8.2e-6)
M_BSIM3 16 6 7a 7a Bsim3 W=9.342 L=0.81e-6 NRS=0 NRD=0
.MODEL Bsim3 NMOS (LEVEL=7 VERSION=3.1 MOBMOD=3 CAPMOD=2 paramchk=1 NQSMOD=0
*Process Parameters
+ TOX=450e-10 ;Oxide thickness
+ XJ=0.58e-6 ;Channel depth
+ NCH=2.14e17 ;Channel concentration
*Channel Current
+ U0=700 VSAT=500000 DROUT=2
+ DELTA=0.08 PSCBE2=1e-5 RSH=0.055e-3
*Threshold voltage
+ VTH0=1.38
*Sub-threshold characteristics
+ VOFF=-0.1 NFACTOR=1.1
*Junction diodes and Capacitance
+ LINT=0.11e-6 DLC=0.11e-6
+ CGSO=62e-12 CGSL=0 CGDO=10e-12 CGDL=60e-12
+ CJ=0 CF=0 CKAPPA=2.2
* Temperature parameters
+ KT1=-1.1 KT2=0 UA1=2e-9
+ NJ=10)
* RevB	1/16/2008	SP
* Updated some electrical properties and added thermal model.
.ENDS

.SUBCKT FDMS8660AS_Thermal_min_pad TH TL
*Thermal Model Subcircuit  16 July 2008
CTHERM1 th c2 0.12
CTHERM2 c2 c3 0.14
CTHERM3 c3 c4 0.5
CTHERM4 c4 c5 0.9
CTHERM5 c5 c6 1
CTHERM6 c6 tl 4.5

RTHERM1 th c2 5.5
RTHERM2 c2 c3 8.5
RTHERM3 c3 c4 10
RTHERM4 c4 c5 17.9
RTHERM5 c5 c6 25
RTHERM6 c6 tl 34.2
.ends FDMS8660AS_Thermal_min_pad