.SUBCKT FDMS86520L 2 1 3
******************************************************************
**      Fairchild Discrete Modeling Group                       **
******************************************************************
**      Website         www.fairchildsemi.com\models            **
******************************************************************
**      (C) Copyright 2009 Fairchild Semiconductor Corporation  **
**                      All rights reserved                     **
**                                                              **
**                      FDMS86520L Spice model                    **
**                      Revision RevA, October 3 , 2011            **
******************************************************************
*Nom Temp 25 deg C
Dbody 7 5 DbodyMOD 
Dbreak 5 11 DbreakMOD 
Lgate 1 9 2.775e-9
Ldrain 2 5 0.004e-9
Lsource 3 7 -0.005e-9
RLgate 1 9 27.75
RLdrain 2 5 0.04
RLsource 3 7 -0.05
Rgate 9 6 0.78
* Shielded  Gate  
D_D1 100 5 D_SG_cap
D_D2 100 101 D_SG_cap
R_R1 101 7 0.62
C_C1 6 101 163e-12
.MODEL D_SG_cap D (IS=1e-9 n=1 RS=5e-3 CJO=1.12e-9 M=0.6 t_abs=25) 
It 7 17 1
Ebreak 11 7 17 7 66
Rbreak 17 7 RbreakMOD 1 
.MODEL RbreakMOD RES (TC1=0.6e-3 TC2=-1e-6)
.MODEL DbodyMOD D (IS=6.85e-12 n=1 RS=4.593e-3 TRS1=1.5e-3 TRS2=1e-6 
+ CJO=1.7e-9 M=0.4 TT=3e-9 XTI=1)
.MODEL DbreakMOD D (RS=30e-3 TRS1=1e-3 TRS2=1e-6 )
Rsource 7a 7 1.738e-3
Rdrain 5 16 RdrainMOD 4e-3
.MODEL RdrainMOD RES (TC1=4.3e-3 TC2=9e-6)
M_BSIM3 16 6 7a 7a Bsim3 W=3.85 L=0.88e-6 NRS=0 NRD=0
.MODEL Bsim3 NMOS (LEVEL=7 VERSION=3.1 MOBMOD=3 CAPMOD=2 paramchk=1 NQSMOD=0
*Process Parameters
+ TOX=500e-10 ;Oxide thickness
+ XJ=0.3e-6 ;Channel depth
+ NCH=2.3e17 ;Channel concentration
*Channel Current
+ U0=950 VSAT=500000 DROUT=1.2
+ DELTA=0.13 PSCBE2=0 RSH=1.738e-3
*Threshold voltage
+ VTH0=1.3
*Sub-threshold characteristics
+ VOFF=-0.1 NFACTOR=1.1
*Junction diodes and Capacitance
+ LINT=0.11e-6 DLC=0.11e-6 
+ CGSO=380e-12 CGSL=0 CGDO=1e-12 CGDL=170e-12 
+ CJ=0 CF=0 CKAPPA=0.8
* Temperature parameters 
+ KT1=-1.1 KT2=0 UA1=3e-9
+ NJ=10)
.ENDS   
*