.SUBCKT FDMS86320 2 1 3
******************************************************************
**      Fairchild Discrete Modeling Group                       **
******************************************************************
**      Website         www.fairchildsemi.com\models            **
******************************************************************
**      (C) Copyright 2009 Fairchild Semiconductor Corporation  **
**                      All rights reserved                     **
**                                                              **
**                      FDMS86320 Spice model                   **
**                      Revision RevA, 02 September 2011        **
******************************************************************
*Nom Temp 25 deg C
Dbody 7 5 DbodyMOD
Dbreak 5 11 DbreakMOD
Lgate 1 9 2.814e-9
Ldrain 2 5 0.004e-9
Lsource 3 7 0.504e-9
RLgate 1 9 28.14
RLdrain 2 5 0.04
RLsource 3 7 5.04
Rgate 9 6 0.43
* Shielded  Gate
D_D1 100 5 D_SG_cap1
D_D2 100 101 D_SG_cap2
R_R1 101 7 0.465
C_C1 6 101 268e-12
.MODEL D_SG_cap1 D (IS=1e-9 n=1 RS=5e-3 CJO=1.44e-9 M=0.54 t_abs=25)
.MODEL D_SG_cap2 D (IS=1e-9 n=1 RS=5e-3 CJO=1.2e-9 M=0.5 t_abs=25)
It 7 17 1
Ebreak 11 7 17 7 89.2
Rbreak 17 7 RbreakMOD 1
.MODEL RbreakMOD RES (TC1=0.68e-3 TC2=-1.2e-6)
.MODEL DbodyMOD D (IS=0.83e-12 n=1 RS=4.737e-3 TRS1=2.5e-3 TRS2=1e-6
+ CJO=0.3e-9 M=0.36 TT=3e-9 XTI=3.3);0.94
.MODEL DbreakMOD D (RS=30e-3 TRS1=1e-3 TRS2=1e-6 )
Rsource 7a 7 0.51e-3
Rdrain 5 16 RdrainMOD 7.6e-3
.MODEL RdrainMOD RES (TC1=5.4e-3 TC2=11e-6)
M_BSIM3 16 6 7a 7a Bsim3 W=3.1 L=0.96e-6 NRS=0 NRD=0
.MODEL Bsim3 NMOS (LEVEL=7 VERSION=3.1 MOBMOD=3 CAPMOD=2 paramchk=1 NQSMOD=0
*Process Parameters
+ TOX=1000e-10 ;Oxide thickness
+ XJ=0.28e-6 ;Channel depth
+ NCH=1.95e17 ;Channel concentration
*Channel Current
+ U0=1000 VSAT=500000 DROUT=1.2
+ DELTA=0.14 PSCBE2=0 RSH=0.51e-3
*Threshold voltage
+ VTH0=3.28
*Sub-threshold characteristics
+ VOFF=-0.43 NFACTOR=1
*Junction diodes and Capacitance
+ LINT=0.16e-6 DLC=0.16e-6
+ CGSO=347e-12 CGSL=0 CGDO=1e-12 CGDL=170e-12 ;433
+ CJ=0 CF=0 CKAPPA=0.25
* Temperature parameters
+ KT1=-2.0 KT2=0 UA1=1e-9
+ NJ=10)
.ENDS