.SUBCKT FDMS86300 2 1 3
+ params: tau=40 igain=350 fs=600 
******************************************************************
**      Fairchild Discrete Modeling Group                       **
******************************************************************
**      Website         www.fairchildsemi.com\models            **
******************************************************************
**      (C) Copyright 2014 Fairchild Semiconductor Corporation  **
**                      All rights reserved                     **
**                                                              **
**                    FDMS86300 Spice model                     **
**                    Revision RevB, 24 Oct 2014                **
******************************************************************
*Nom Temp 25 deg C
Dbreak 5 11 DbreakMOD
Lgate 1 9 1.884e-9
Ldrain 2 5 0.004e-9
Lsource 3 7 0.329e-9
RLgate 1 9 18.84
RLdrain 2 5 0.04
RLsource 3 7 3.29
Rgate 9 6 0.37
H1   161 141 V_H1 {tau}
V_H1 151 7 0V
V10  5 161 0
F1   7 161 V_F1 {-igain}
V_F1 171 141 0V
D2   151 161 DbodyMOD
.MODEL DbodyMOD D (IS=3.5e-12 n=1 RS=1.5e-3 TRS1=2.7e-3 TRS2=1e-6
+ CJO=1.07e-9 M=0.35 TT=0 XTI=3.5)
R9   131 171  {tau*fs}
C2   161 131  1p
* Shielded  Gate
D_D1 100 5 D_SG_cap
D_D2 100 101 D_SG_cap
R_R1 101 7 0.039
C_C1 6 101 706e-12
.MODEL D_SG_cap D (IS=1e-9 n=1 RS=0.8e-3 CJO=3.2e-9 M=0.4 t_abs=25)
It 7 17 1
Ebreak 11 7 17 7 85
Rbreak 17 7 RbreakMOD 1
.MODEL RbreakMOD RES (TC1=0.5e-3 TC2=-0.8e-6)
.MODEL DbreakMOD D (RS=30e-3 TRS1=1e-3 TRS2=1e-6)
Rsource 7a 7 0.405e-3
Rdrain 5 16 RdrainMOD 2.07e-3
.MODEL RdrainMOD RES (TC1=6.3e-3 TC2=19e-6)
M_BSIM3 16 6 7a 7a Bsim3 W=8.83 L=0.96e-6 NRS=0 NRD=0 as=1e-20 ps=1e-14 pd=1e-14
.MODEL Bsim3 NMOS (LEVEL=7 VERSION=3.1 MOBMOD=3 CAPMOD=2 paramchk=1 NQSMOD=0
*Process Parameters
+ TOX=1000e-10 ;Oxide thickness
+ XJ=0.28e-6 ;Channel depth
+ NCH=1.8e17 ;Channel concentration
*Channel Current
+ U0=800 VSAT=500000 DROUT=1.2
+ DELTA=0.14 PSCBE2=0 RSH=0.405e-3
*Threshold voltage
+ VTH0=2.95
*Sub-threshold characteristics
+ VOFF=-0.1 NFACTOR=1
*Junction diodes and Capacitance
+ LINT=0.16e-6 DLC=0.16e-6
+ CGSO=320e-12 CGSL=0 CGDO=1e-12 CGDL=180e-12
+ CJ=0 CF=0 CKAPPA=0.25
* Temperature parameters
+ KT1=-2.2 KT2=0 UA1=1e-9
+ NJ=10)
.ENDS