.SUBCKT FDMS86201 2 1 3
******************************************************************
**      Fairchild Discrete Modeling Group                       **
******************************************************************
**      Website         www.fairchildsemi.com\models            **
******************************************************************
**      (C) Copyright 2009 Fairchild Semiconductor Corporation  **
**                      All rights reserved                     **
**                                                              **
**                      FDMS86201 Spice model                   **
**                    Revision RevB, 27 Jan 2011                **
******************************************************************
*Nom Temp 25 deg C
Dbody 7 5 DbodyMOD
Dbreak 5 11 DbreakMOD
Lgate 1 9 1.924e-9
Ldrain 2 5 0.004e-9
Lsource 3 7 0.326e-9
RLgate 1 9 19.24
RLdrain 2 5 0.04
RLsource 3 7 3.26
Rgate 9 6 0.5
* Shielded  Gate
D_D1 100 5 D_SG_cap
D_D2 100 101 D_SG_cap
R_R1 101 7 1.01
C_C1 6 101 185e-12
.MODEL D_SG_cap D (IS=1e-9 n=1 RS=4e-3 CJO=2.7e-9 M=0.62 t_abs=25)
It 7 17 1
Ebreak 11 7 17 7 126.85; 110
Rbreak 17 7 RbreakMOD 1
.MODEL RbreakMOD RES (TC1=0.8e-3 TC2=-0.4e-6)
.MODEL DbodyMOD D (IS=10e-12 n=1 RS=3.65e-3 TRS1=2.6e-3 TRS2=1e-6
+ CJO=0.66e-9 M=0.47 TT=0.1e-9 XTI=2.5)
.MODEL DbreakMOD D (RS=30e-3 TRS1=1e-3 TRS2=1e-6 )
Rsource 7a 7 0.359e-3
Rdrain 5 16 RdrainMOD 6.9e-3
.MODEL RdrainMOD RES (TC1=7.20e-3 TC2=20e-6)
M_BSIM3 16 6 7a 7a Bsim3 W=5.12 L=1.2e-6 NRS=0 NRD=0
.MODEL Bsim3 NMOS (LEVEL=7 VERSION=3.1 MOBMOD=3 CAPMOD=2 paramchk=1 NQSMOD=0
*Process Parameters
+ TOX=1000e-10 ;Oxide thickness
+ XJ=0.5e-6 ;Channel depth
+ NCH=0.8e17 ;Channel concentration
*Channel Current
+ U0=640 VSAT=500000 DROUT=1.8
+ DELTA=0.02 PSCBE2=0.00001 RSH=0.359e-3
*Threshold voltage
+ VTH0=2.95
*Sub-threshold characteristics
+ VOFF=-0.15 NFACTOR=1.1
*Junction diodes and Capacitance
+ LINT=0.22e-6 DLC=0.24e-6
+ CGSO=144e-12 CGSL=0 CGDO=7e-12 CGDL=125e-12
+ CJ=0 CF=0 CKAPPA=0.25
* Temperature parameters
+ KT1=-1.8 KT2=0 UA1=6e-9
+ NJ=10)
.ENDS