* PSpice Model Editor - Version 16.5.0
*$
.SUBCKT FDMS86200 2 1 3
******************************************************************
**      Fairchild Discrete Modeling Group                       **
******************************************************************
**      Website         www.fairchildsemi.com\models            **
******************************************************************
**      (C) Copyright 2009 Fairchild Semiconductor Corporation  **
**                      All rights reserved                     **
**                                                              **
**                      FDMS86200 Spice model                   **
**                      Revision RevB, 24 Feb 2012              **
******************************************************************		
*Nom Temp 25 deg C		
Dbody 7 5 DbodyMOD 		
Dbreak 5 11 DbreakMOD 		
Lgate 1 9 1.959e-9		
Ldrain 2 5 0.004e-9		
Lsource 3 7 0.575e-9		
RLgate 1 9 19.59		
RLdrain 2 5 0.04		
RLsource 3 7 5.7		
Rgate 9 6 1.2		
* Shielded  Gate  		
D_D1 100 5 D_SG_cap1		
D_D2 100 101 D_SG_cap2		
R_R1 101 7 0.6		
C_C1 6 101 175e-12		
.MODEL D_SG_cap1 D (IS=1e-9 n=1 RS=5e-3 CJO=1.7e-9 M=0.6 t_abs=25)
.MODEL D_SG_cap2 D (IS=1e-9 n=1 RS=5e-3 CJO=3.5e-9 M=0.6 t_abs=25) 		
It 7 17 1		
Ebreak 11 7 17 7 159.3		
Rbreak 17 7 RbreakMOD 1 		
.MODEL RbreakMOD RES (TC1=0.73e-3 TC2=-1e-6)		
.MODEL DbodyMOD D (IS=10e-12 n=1 RS=3e-3 TRS1=1e-3 TRS2=1e-6 		
+ CJO=0.8e-9 M=0.6 TT=1e-9 XTI=2.7)	;2.4	
.MODEL DbreakMOD D (RS=8e-3 TRS1=1e-3 TRS2=1e-6 )		
Rsource 7a 7 0.388e-3		
Rdrain 5 16 RdrainMOD 12.5e-3		
.MODEL RdrainMOD RES (TC1=8e-3 TC2=23e-6)		
M_BSIM3 16 6 7a 7a Bsim3 W=5.16 L=1.1e-6 NRS=0 NRD=0		
.MODEL Bsim3 NMOS (LEVEL=7 VERSION=3.1 MOBMOD=3 CAPMOD=2 paramchk=1 NQSMOD=0		
*Process Parameters		
+ TOX=1000e-10 ;Oxide thickness		
+ XJ=0.54e-6 ;Channel depth		
+ NCH=0.96e17 ;Channel concentration		
*Channel Current		
+ U0=800 VSAT=500000 DROUT=1.8		
+ DELTA=0.12 PSCBE2=0 RSH=0.535e-3		
*Threshold voltage		
+ VTH0=2.97		
*Sub-threshold characteristics		
+ VOFF=-0.3 NFACTOR=1		
*Junction diodes and Capacitance		
+ LINT=0.175e-6 DLC=0.175e-6 		
+ CGSO=138e-12 CGSL=0 CGDO=0.1e-12 CGDL=135e-12 ;172		
+ CJ=0 CF=0 CKAPPA=0.25		
* Temperature parameters 		
+ KT1=-1.6 KT2=0 UA1=3e-9		
+ NJ=10)		
.ENDS   		
* 		
*$