.SUBCKT FDMS86150 2 1 3
+ params: tau=50 igain=600 fs=400 
******************************************************************
**      Fairchild Discrete Modeling Group       	            **
******************************************************************
**      Website: www.fairchildsemi.com\models                   **
******************************************************************
**   (C) Copyright 2012 Fairchild Semiconductor Corporation     **
**                All rights reserved                     		**
**                                                              **
**              FDMS86150 Spice model                   	    **
**           Revision RevA, 3 September 2012               		**
**           RevA1 3 Dec 2014,  Improved trr/Qrr                **
******************************************************************
*Nom Temp 25 deg C
Dbreak 5 11 DbreakMOD
Lgate 1 9 0.853e-9
Ldrain 2 5 0.004e-9
Lsource 3 7 0.007e-9
RLgate 1 9 8.53
RLdrain 2 5 0.04
RLsource 3 7 0.07
Rgate 9 6 0.28
H1   161 141 V_H1 {tau}
V_H1 151 7 0V
V10  5 161 0
F1   7 161 V_F1 {-igain}
V_F1 171 141 0V
D2   151 161 DbodyMOD
.MODEL DbodyMOD D (IS=2.55e-12 n=1 RS=0.8e-3 TRS1=2.5e-3 TRS2=1e-6
+ CJO=1.05e-9 M=0.405 TT=0 XTI=3.5)
R9   131 171  {tau*fs}
C2   161 131  1p
D_D1 100 5 D_SG_cap
D_D2 100 101 D_SG_cap
R_R1 101 7 0.22
C_C1 6 101 226e-12
.MODEL D_SG_cap D (IS=1e-9 n=1 RS=5e-3 CJO=4.08e-9 M=0.546 t_abs=25)
It 7 17 1
Ebreak 11 7 17 7 108.5
Rbreak 17 7 RbreakMOD 1
.MODEL RbreakMOD RES (TC1=0.7e-3 TC2=-0.5e-6)
.MODEL DbreakMOD D (RS=8e-3 TRS1=1e-3 TRS2=1e-6 )
Rsource 77 7 0.489e-3
Rdrain 5 16 RdrainMOD 2.45e-3
.MODEL RdrainMOD RES (TC1=7.5e-3 TC2=29e-6)
M_BSIM3 16 6 77 77 Bsim3 W=7.53314285714286 L=1.15e-6 NRS=0 NRD=0
.MODEL Bsim3 NMOS (LEVEL=7 VERSION=3.1 MOBMOD=3 CAPMOD=2 paramchk=1 NQSMOD=0
+ TOX=1000e-10
+ XJ=0.62e-6
+ NCH=0.96e17
+ U0=700 VSAT=500000 DROUT=1.8
+ DELTA=0.03 PSCBE2=0 RSH=0.489e-3
+ VTH0=3.6
+ VOFF=-0.13 NFACTOR=1.4
+ LINT=0.175e-6 DLC=0.175e-6
+ CGSO=120e-12 CGSL=0 CGDO=0.1e-12 CGDL=120e-12
+ CJ=0 CF=0 CKAPPA=0.67
+ KT1=-2.1 KT2=0 UA1=10e-9
+ NJ=10)
.ENDS FDMS86150

*Thermal model with min pad area of 2oz copper
*08/20/2014
.SUBCKT FDMS86150_Rthja TH TL
CTHERM1 TH 6 1.0e-2
CTHERM2 6 5  1.2e-2
CTHERM3 5 4  9e-2
CTHERM4 4 3  13e-2
CTHERM5 3 2  2.7e-1
CTHERM6 2 TL 1.3
RTHERM1 TH 6 0.2
RTHERM2 6 5  0.5
RTHERM3 5 4  1.0
RTHERM4 4 3  10
RTHERM5 3 2  33
RTHERM6 2 TL 56
.ENDS FDMS86150_Rthja

.SUBCKT FDMS86150_JC TH TL
*Thermal Model Subcircuit  12-5-2014
*Foster model
CTHERM1 th 6 4.8e-3
CTHERM2 6 5 1.0e-2
CTHERM3 5 4 2.0e-2
CTHERM4 4 3 7.0e-2
CTHERM5 3 2 10e-2
CTHERM6 2 tl 2e-1

RTHERM1 th 6 .02
RTHERM2 6 5 .04
RTHERM3 5 4 .05
RTHERM4 4 3 0.07
RTHERM5 3 2 0.18
RTHERM6 2 tl 0.32
.ends FDMS86150_JC

.SUBCKT FDMS86150_JC_cauer TH TL
*12-5-2014
*Cauer model
ctherm1 th 0 0.00257
ctherm2 2 0  0.00543
ctherm3 3 0  0.0177
ctherm4 4 0  0.0238
ctherm5 5 0  0.0748
ctherm6 6 0  0.385

rtherm1 th 2 0.0607
rtherm2 2 3  0.0767
rtherm3 3 4  0.0803
rtherm4 4 5  0.176
rtherm5 5 6  0.179
rtherm6 6 0  0.106
.ends FDMS86150_JC_cauer