.SUBCKT FDMS86101DC 2 1 3
******************************************************************
**      Fairchild Discrete Modeling Group                       **
******************************************************************
**      Website         www.fairchildsemi.com\models            **
******************************************************************
**      (C) Copyright 2013 Fairchild Semiconductor Corporation  **
**                      All rights reserved                     **
**                                                              **
**                      FDMS86101DC Spice model                  **
**                    Revision Rev-A, 6 Jan 2013                **
******************************************************************
*Nom Temp 25 deg C
Dbody 7 5 DbodyMOD 
Dbreak 5 11 DbreakMOD 
Lgate 1 9 2.714e-9
Ldrain 2 5 0.004e-9
Lsource 3 7 0.44e-9
RLgate 1 9 27.14
RLdrain 2 5 0.04
RLsource 3 7 4.4
Rgate 9 6 0.73
D_D1 100 5 D_SG_cap
D_D2 100 101 D_SG_cap
R_R1 101 7 0.05
C_C1 6 101 364e-12
.MODEL D_SG_cap D (IS=1e-9 n=1 RS=5e-3 CJO=2.97e-9 M=0.6 t_abs=25) 
It 7 17 1
Ebreak 11 7 17 7 108.7
Rbreak 17 7 RbreakMOD 1 
.MODEL RbreakMOD RES (TC1=0.69e-3 TC2=-0.45e-6)
.MODEL DbodyMOD D (IS=1e-12 n=1 RS=1.675e-3 TRS1=4e-3 TRS2=1e-6 
+ CJO=0.77e-9 M=0.45 TT=1e-9 XTI=4.7)
.MODEL DbreakMOD D (RS=8e-3 TRS1=1e-3 TRS2=1e-6 )
Rsource 7a 7 0.591e-3
Rdrain 5 16 RdrainMOD 4.2e-3
.MODEL RdrainMOD RES (TC1=6.7e-3 TC2=19e-6)
M_BSIM3 16 6 7a 7a Bsim3 W=5.05142857142857 L=1.15e-6 NRS=0 NRD=0
.MODEL Bsim3 NMOS (LEVEL=7 VERSION=3.1 MOBMOD=3 CAPMOD=2 paramchk=1 NQSMOD=0
+ TOX=1000e-10 
+ XJ=0.62e-6 
+ NCH=0.96e17 
+ U0=1120 VSAT=500000 DROUT=1.8
+ DELTA=0.04 PSCBE2=0 RSH=0.591e-3
+ VTH0=3.48
+ VOFF=-0.09 NFACTOR=1
+ LINT=0.175e-6 DLC=0.175e-6 
+ CGSO=288e-12 CGSL=0 CGDO=1e-12 CGDL=95e-12 
+ CJ=0 CF=0 CKAPPA=0.75
+ KT1=-1.8 KT2=0 UA1=7e-9
+ NJ=10)
.ENDS