* PSpice Model Editor - Version 16.0.0
*$
.SUBCKT FDMS86101 2 1 3
******************************************************************
**      Fairchild Discrete Modeling Group                       **
******************************************************************
**      Website         www.fairchildsemi.com\models            **
******************************************************************
**      (C) Copyright 2009 Fairchild Semiconductor Corporation  **
**                      All rights reserved                     **
**                                                              **
**                      FDMS86101 Spice model                   **
**                      Revision RevB, 10 July 2012             **
******************************************************************			
*Nom Temp 25 deg C
Dbody 7 5 DbodyMOD
Dbreak 5 11 DbreakMOD
Lgate 1 9 2.191e-9
Ldrain 2 5 0.004e-9
Lsource 3 7 0.292e-9
RLgate 1 9 21.91
RLdrain 2 5 0.04
RLsource 3 7 2.92
Rgate 9 6 1
* Shielded  Gate  		
D_D1 100 5 D_SG_cap1		
D_D2 100 101 D_SG_cap2		
R_R1 101 7 0.43		
C_C1 6 101 192e-12		
.MODEL D_SG_cap1 D (IS=1e-9 n=1 RS=5e-3 CJO=3e-9 M=0.58 t_abs=25)
.MODEL D_SG_cap2 D (IS=1e-9 n=1 RS=5e-3 CJO=1.5e-9 M=0.5 t_abs=25)  
It 7 17 1
Ebreak 11 7 17 7 109.3
Rbreak 17 7 RbreakMOD 1
.MODEL RbreakMOD RES (TC1=0.67e-3 TC2=-0.6e-6)
.MODEL DbodyMOD D (IS=3.4e-12 n=1 RS=2e-3 TRS1=0.7e-3 TRS2=1e-6
+ CJO=0.62e-9 M=0.4 TT=0.1e-9 XTI=2.5);1.85
.MODEL DbreakMOD D (RS=30e-3 TRS1=1e-3 TRS2=1e-6 )
Rsource 7a 7 0.668e-3
Rdrain 5 16 RdrainMOD 4e-3
.MODEL RdrainMOD RES (TC1=8e-3 TC2=2.3e-5)
M_BSIM3 16 6 7a 7a Bsim3 W=5.05 L=4.9e-6 NRS=0 NRD=0
.MODEL Bsim3 NMOS (LEVEL=7 VERSION=3.1 MOBMOD=3 CAPMOD=2 paramchk=1 NQSMOD=0
*Process Parameters
+ TOX=1000e-10 ;Oxide thickness
+ XJ=0.7e-6 ;Channel depth
+ NCH=9.6e16 ;Channel concentration
*Channel Current
+ U0=630 VSAT=5e5 DROUT=1.6
+ DELTA=0.01 PSCBE2=0.00001 RSH=0.668e-3
*Threshold voltage
+ VTH0=3.28
*Sub-threshold characteristics
+ VOFF=-0.08 NFACTOR=1
*Junction diodes and Capacitance
+ LINT=2.05e-6 DLC=2.05e-6
+ CGSO=150e-12 CGSL=0e-12 CGDO=2.5e-12 CGDL=180e-12 ;188
+ CJ=0 CF=0 CKAPPA=1
* Temperature parameters
+ KT1=-1.7 KT2=0 UA1=3.4e-9
+ NJ=10)
.ENDS
*$