.SUBCKT FDMS8570SDC 2 1 3
******************************************************************
**      Fairchild Discrete Modeling Group                       **
******************************************************************
**      Website         www.fairchildsemi.com\models            **
******************************************************************
**      (C) Copyright 2013 Fairchild Semiconductor Corporation  **
**                      All rights reserved                     **
**                                                              **
**                   FDMS8570SDC Spice model (25V, 49A)         **
**                    Revision Rev-A, 30 Apr 2013               **
******************************************************************
*Nom Temp 25 deg C
Dbody 7 5 DbodyMOD 
Dschottky 7 5 DSchottkyMOD 
Dbreak 5 11 DbreakMOD 
Lgate 1 9 0.765e-9
Ldrain 2 5 0.004e-9
Lsource 3 7 0.218e-9
RLgate 1 9 7.65
RLdrain 2 5 0.04
RLsource 3 7 2.18
Rgate 9 6 0.9
D_D1 100 5 D_SG_cap
D_D2 100 101 D_SG_cap
R_R1 101 7 0.46
C_C1 6 101 359e-12
.MODEL D_SG_cap D (IS=1e-9 n=1 RS=5e-3 CJO=1.8e-9 M=0.53 t_abs=25) 
It 7 17 1
Ebreak 11 7 17 7 29.8
Rbreak 17 7 RbreakMOD 1 
.MODEL RbreakMOD RES (TC1=0.9e-3 TC2=-1e-6)
.MODEL DbodyMOD D (IS=2.4e-12 n=1 RS=1.2e-3 TRS1=1.5e-3 TRS2=1e-6 
+ CJO=0.23e-9 M=0.368 TT=3e-9 XTI=1.5)
.MODEL DSchottkyMOD D (IS=4.3e-6 n=1.05 RS=110e-3 TRS1=3e-3 TRS2=1e-6 
+ CJO=0.23e-9 M=0.368 TT=3e-9 XTI=-18)
.MODEL DbreakMOD D (RS=30e-3 TRS1=1e-3 TRS2=1e-6 )
Rsource 7a 7 0.202e-3
Rdrain 5 16 RdrainMOD 1.4e-3
.MODEL RdrainMOD RES (TC1=3.65e-3 TC2=10e-6)
M_BSIM3 16 6 7a 7a Bsim3 W=4.49141425 L=0.71e-6 NRS=0 NRD=0
.MODEL Bsim3 NMOS (LEVEL=7 VERSION=3.1 MOBMOD=3 CAPMOD=2 paramchk=1 NQSMOD=0
+ TOX=500e-10
+ XJ=0.16e-6 
+ NCH=1.2e17 
+ U0=850 VSAT=500000 DROUT=1.2
+ DELTA=0.04 PSCBE2=0 RSH=0.202e-3
+ VTH0=1.6
+ VOFF=-0.08 NFACTOR=0.8
+ LINT=0.165e-6 DLC=0.165e-6 
+ CGSO=320e-12 CGSL=0 CGDO=12e-12 CGDL=195e-12 
+ CJ=0 CF=0 CKAPPA=0.7 
+ KT1=-0.78 KT2=0 UA1=0.55e-9
+ NJ=10)
.ENDS   
*