* PSpice Model Editor - Version 10.5.0
*$
.SUBCKT FDMS8460 2 1 3    
*Nom Temp=25 deg C
Dbody 7 5 DbodyMOD
Dbreak 5 11 DbreakMOD
Ebreak 11 7 17 7 44
Lgate 1 9 2.185e-9
Ldrain 2 5 0.004e-9
Lsource 3 7 0.103e-9
RLgate 1 9 21.85
RLdrain 2 5 0.04
RLsource 3 7 1.03
Rgate 9 6 1.4
It 7 17 1
Rbreak 17 7 RbreakMOD 1
.MODEL RbreakMOD RES (TC1=7.8e-4 TC2=-1e-6)
.MODEL DbodyMOD D (IS=3.927e-12 n=1 RS=0.85E-3 TRS1=3.8e-4 TRS2=1e-6
+ CJO=4.1e-9 M=0.45 TT=0.1e-9 XTI=2.3)
.MODEL DbreakMOD D (RS=8e-3 TRS1=1e-3 TRS2=0)
Rdrain 5 16 RdrainMOD 1.15e-3
.MODEL RdrainMOD RES (TC1=4.5e-3 TC2=3.1e-6)
M_BSIM3 16 6 7 7 Bsim3 W=10.37 L=0.91e-6 NRS=1 NRD=0
.MODEL Bsim3 NMOS (LEVEL=7 VERSION=3.1 MOBMOD=3 CAPMOD=2 paramchk=1 NQSMOD=0)
**Process Parameters
+ TOX=450e-10 ;Oxide thickness
+ XJ=0.675u ;Channel depth
+ NCH=1.9e17 ;Channel concentration
**Channel Current
+ U0=700 VSAT=5e5 DROUT=1
+ DELTA=0.1 PSCBE2=0 RSH=0.54e-3   
**Threshold voltage
+ VTH0=1.6
**Sub-threshold characteristics
+ VOFF=-0.1 NFACTOR=1.1
**Junction diodes and Capacitance
+ LINT=0.14e-6 DLC=0.14e-6 
+ CGSO=85e-12 CGSL=0 CGDO=5e-12 CGDL=108e-12
+ CJ=0 CF=0 CKAPPA=1.5
** Temperature parameters
+ KT1=-1.3 KT2=0 UA1=3.2e-9
+ NJ=10)
.ENDS
*FDMS8460(Rev.A) 1/11/2008
*ST
*$