.SUBCKT FDMS8350L 2 1 3
+params: tau=100 igain=20 fs=1500
*******************************************************************
**      Fairchild Discrete Modeling Group                        **
*******************************************************************
**      Website         www.fairchildsemi.com\models             **
*******************************************************************
**      (C) Copyright 2013 Fairchild Semiconductor Corporation   **
**                      All rights reserved                      **
**                                                               **
**                    FDMS8350L Spice model                      **
**                    Revision RevA, 20 November 2013            **
*******************************************************************
*Nom Temp 25 deg C
Dbreak 5 11 DbreakMOD
Lgate 1 9 0.853e-9
Ldrain 2 5 0.004e-9
Lsource 3 7 0.006e-9
RLgate 1 9 8.53
RLdrain 2 5 0.04
RLsource 3 7 0.06
Rgate 9 6 1
H1   161 141 V_H1 {tau}
V_H1 151 7 0V
V10  5 161 0
F1   7 161 V_F1 {-igain}
V_F1 171 141 0V
D3   151 161 Dbody_trr
.MODEL Dbody_trr D (IS=2e-12 n=0.915 RS=0.57e-3 TRS1=3.8e-3 TRS2=2.5e-6
+ CJO=2.5e-9 M=0.3 TT=0 XTI=3.5)
R9   131 171  {tau*fs}
C2   161 131  1p
D_D1 100 5 D_SG_cap
D_D2 100 101 D_SG_cap
R_R1 101 7 0.86
C_C1 6 101 2778e-12
.MODEL D_SG_cap D (IS=1e-9 n=1 RS=5e-3 CJO=13.26e-9 M=0.6 t_abs=25)
It 7 17 1
Ebreak 11 7 17 7 47.9
Rbreak 17 7 RbreakMOD 1
.MODEL RbreakMOD RES (TC1=0.66e-3 TC2=-1.65e-6)
.MODEL DbreakMOD D (RS=30e-3 TRS1=1e-3 TRS2=1e-6 )
Rsource 7a 7 0.109e-3
Rdrain 5 16 RdrainMOD 0.52e-3
.MODEL RdrainMOD RES (TC1=3.35e-3 TC2=6.8e-6)
M_BSIM3 16 6 7a 7a Bsim3 W=25.53 L=0.624e-6 NRS=0 NRD=0
.MODEL Bsim3 NMOS (LEVEL=7 VERSION=3.1 MOBMOD=3 CAPMOD=2 paramchk=1 NQSMOD=0
+ TOX=500e-10
+ XJ=0.22e-6
+ NCH=1.4e17
+ U0=650 VSAT=500000 DROUT=1.2
+ DELTA=0.3 PSCBE2=0 RSH=0.109e-3
+ VTH0=1.59
+ VOFF=0.1 NFACTOR=1.4
+ LINT=0.11e-6 DLC=0.11e-6
+ CGSO=168e-12 CGSL=0 CGDO=1.8e-12 CGDL=97e-12
+ CJ=0 CF=0 CKAPPA=0.75
+ KT1=-1.18 KT2=0 UA1=15e-9
+ NJ=10)
.ENDS

.SUBCKT FDMS8350L_JC TH TL
*Thermal Model Subcircuit  6-19-2014
*Foster model
CTHERM1 th 6 4.5e-3
CTHERM2 6 5 1.0e-2
CTHERM3 5 4 5.0e-2
CTHERM4 4 3 7.0e-2
CTHERM5 3 2 8.5e-2
CTHERM6 2 tl 1.2e-1

RTHERM1 th 6 .02
RTHERM2 6 5 .08
RTHERM3 5 4 .15
RTHERM4 4 3 0.18
RTHERM5 3 2 0.24
RTHERM6 2 tl 0.34
.ends

.SUBCKT FDMS8350L_JC_cauer TH TL
*6-19-2014
*Cauer model
ctherm1 th 0 2.584e-3
ctherm2 2 0 4.944e-3
ctherm3 3 0 0.014
ctherm4 4 0 0.083
ctherm5 5 0 0.389
ctherm6 6 0 0.293

rtherm1 th 2 0.0528
rtherm2 2 3 0.163
rtherm3 3 4 0.552
rtherm4 4 5 0.184
rtherm5 5 6 0.05
rtherm6 6 0 0.00729
.ends