.SUBCKT FDMS8333L 2 1 3
******************************************************************
**      Fairchild Discrete Modeling Group                       **
******************************************************************
**      Website         www.fairchildsemi.com\models            **
******************************************************************
**      (C) Copyright 2009 Fairchild Semiconductor Corporation  **
**                      All rights reserved                     **
**                                                              **
**                      FDMS8333L Spice model                     **
**                      Revision RevA, 26 April 2013              **
******************************************************************	
*Nom Temp 25 deg C
Dbody 7 5 DbodyMOD
Dbreak 5 11 DbreakMOD 
Lgate 1 9 2.801e-9
Ldrain 2 5 0.004e-9
Lsource 3 7 0.505e-9
RLgate 1 9 28.01
RLdrain 2 5 0.04
RLsource 3 7 5.05
Rgate 9 6 1.31
D_D1 100 5 D_SG_cap
D_D2 100 101 D_SG_cap
R_R1 101 7 1.66
C_C1 6 101 198e-12
.MODEL D_SG_cap D (IS=1e-9 n=1 RS=5e-3 CJO=0.8	e-9 M=1.0 t_abs=25) 
It 7 17 1
Ebreak 11 7 17 7 44
Rbreak 17 7 RbreakMOD 1 
.MODEL RbreakMOD RES (TC1=0.65e-3 TC2=-1e-6)
.MODEL DbodyMOD D (IS=4.2e-12 n=1 RS=4.562e-3 TRS1=4.9e-3 TRS2=1e-6 
+ CJO=2.8e-9 M=0.45 TT=3e-9 XTI=1)
.MODEL DbreakMOD D (RS=30e-3 TRS1=1e-3 TRS2=1e-6 )
Rsource 7a 7 0.604e-3
Rdrain 5 16 RdrainMOD 1.466e-3
.MODEL RdrainMOD RES (TC1=10e-3 TC2=20e-6)
M_BSIM3 16 6 7a 7a Bsim3 W=6.23 L=0.624e-6 NRS=0 NRD=0
.MODEL Bsim3 NMOS (LEVEL=7 VERSION=3.1 MOBMOD=3 CAPMOD=2 paramchk=1 NQSMOD=0
+ TOX=500e-10 
+ XJ=0.22e-6 
+ NCH=1.4e17
+ U0=750 VSAT=500000 DROUT=1.2
+ DELTA=0.05 PSCBE2=0 RSH=0.604e-3
+ VTH0=2
+ VOFF=-0.1 NFACTOR=1.1
+ LINT=0.11e-6 DLC=0.11e-6 
+ CGSO=315e-12 CGSL=0 CGDO=1e-12 CGDL=125e-12 
+ CJ=0 CF=0 CKAPPA=0.3
+ KT1=-1.1 KT2=0 UA1=6e-9
+ NJ=10)
.ENDS