.SUBCKT FDMS8090 2 1 3
******************************************************************
**      Fairchild Discrete Modeling Group                       **
******************************************************************
**      Website         www.fairchildsemi.com\models            **
******************************************************************
**      (C) Copyright 2012 Fairchild Semiconductor Corporation  **
**                      All rights reserved                     **
**                                                              **
**                      FDMS8090 Spice model                    **
**                    Revision RevA, 04 Oct 2012                **
******************************************************************
*Nom Temp 25 deg C
Dbody 7 5 DbodyMOD 
Dbreak 5 11 DbreakMOD 
Lgate 1 9 0.975e-9
Ldrain 2 5 0.004e-9
Lsource 3 7 0.185e-9
RLgate 1 9 9.75
RLdrain 2 5 0.04
RLsource 3 7 1.85
Rgate 9 6 0.54
D_D1 100 5 D_SG_cap
D_D2 100 101 D_SG_cap
R_R1 101 7 0.47
C_C1 6 101 103e-12
.MODEL D_SG_cap D (IS=1e-9 n=1 RS=5e-3 CJO=1.75e-9 M=0.54 t_abs=25) 
It 7 17 1
Ebreak 11 7 17 7 108.6
Rbreak 17 7 RbreakMOD 1 
.MODEL RbreakMOD RES (TC1=0.7e-3 TC2=-0.25e-6)
.MODEL DbodyMOD D (IS=1.5e-12 n=1 RS=3.0e-3 TRS1=3.5e-3 TRS2=1e-6 
+ CJO=0.443e-9 M=0.395 TT=1e-9 XTI=4.2)
.MODEL DbreakMOD D (RS=8e-3 TRS1=1e-3 TRS2=1e-6 )
Rsource 7a 7 0.489e-3
Rdrain 5 16 RdrainMOD 7.5e-3
.MODEL RdrainMOD RES (TC1=6e-3 TC2=15e-6)
M_BSIM3 16 6 7a 7a Bsim3 W=3.23 L=1.15e-6 NRS=0 NRD=0
.MODEL Bsim3 NMOS (LEVEL=7 VERSION=3.1 MOBMOD=3 CAPMOD=2 paramchk=1 NQSMOD=0
+ TOX=1000e-10 
+ XJ=0.62e-6 
+ NCH=0.96e17 
+ U0=700 VSAT=500000 DROUT=1.8
+ DELTA=0.04 PSCBE2=0 RSH=0.489e-3
*Threshold voltage
+ VTH0=3.8
+ VOFF=-0.13 NFACTOR=1.4
+ LINT=0.175e-6 DLC=0.175e-6 
+ CGSO=128e-12 CGSL=0 CGDO=0.5e-12 CGDL=115e-12 
+ CJ=0 CF=0 CKAPPA=0.8
* Temperature parameters 
+ KT1=-2.3 KT2=0 UA1=10e-9
+ NJ=10)
.ENDS   
*