.SUBCKT FDMS8050 2 1 3
******************************************************************
**     		   Fairchild Discrete Modeling Group   	            **
******************************************************************
**           Website www.fairchildsemi.com\models               **
******************************************************************
**      (C) Copyright 2013 Fairchild Semiconductor Corporation  **
**                      All rights reserved                     **
**                                                              **
**                      FDMS8050 Spice model 		            **
**                    Revision RevA, 28 May 2013                **
******************************************************************
*Nom Temp 25 deg C
Dbody 7 5 DbodyMOD
Dbreak 5 11 DbreakMOD 
Lgate 1 9 0.853e-9
Ldrain 2 5 0.004e-9
Lsource 3 7 0.003e-9
RLgate 1 9 8.53
RLdrain 2 5 0.04
RLsource 3 7 0.03
Rgate 9 6 0.91
D_D1 100 5 D_SG_cap
D_D2 100 101 D_SG_cap
R_R1 101 7 0.424
C_C1 6 101 1371e-12
.MODEL D_SG_cap D (IS=1e-9 n=1 RS=1.97e-3 CJO=14.95e-9 M=0.518 t_abs=25) 
It 7 17 1
Ebreak 11 7 17 7 33.6
Rbreak 17 7 RbreakMOD 1 
.MODEL RbreakMOD RES (TC1=0.7e-3 TC2=-2e-6)
.MODEL DbodyMOD D (IS=45e-12 n=1 RS=0.48e-3 TRS1=4.0e-3 TRS2=1e-6 
+ CJO=3.8e-9 M=0.35 TT=3e-9 XTI=1)
.MODEL DbreakMOD D (RS=30e-3 TRS1=1e-3 TRS2=1e-6 )
Rsource 7a 7 0.109e-3
Rdrain 5 16 RdrainMOD 0.31e-3
.MODEL RdrainMOD RES (TC1=1.8e-3 TC2=0.1e-6)
M_BSIM3 16 6 7a 7a Bsim3 W=35.12175 L=0.48e-6 NRS=0 NRD=0
.MODEL Bsim3 NMOS (LEVEL=7 VERSION=3.1 MOBMOD=3 CAPMOD=2 paramchk=1 NQSMOD=0
+ TOX=500e-10
+ XJ=0.195e-6
+ NCH=1.38e17
+ U0=715 VSAT=500000 DROUT=1.2
+ DELTA=0.4 PSCBE2=0 RSH=0.109e-3
+ VTH0=1.6
+ VOFF=-0.08 NFACTOR=0.8
+ LINT=0.08e-6 DLC=0.08e-6 
+ CGSO=156e-12 CGSL=0 CGDO=2.4e-12 CGDL=130e-12 
+ CJ=0 CF=0 CKAPPA=1
* Temperature parameters
+ KT1=-0.8 KT2=0 UA1=32e-9
+ NJ=10)
.ENDS
*