.SUBCKT FDMS7680 2 1 3
******************************************************************
**      Fairchild Discrete Modeling Group                       **
******************************************************************
**      Website         www.fairchildsemi.com\models            **
**      Scott Pearson   scott.pearson@fairchildsemi.com         **
**      Chris Hanas     chris.hanas@fairchildsemi.com           **
******************************************************************
**      (C) Copyright 2009 Fairchild Semiconductor Corporation  **
**                      All rights reserved                     **
**                                                              **
**                      FDMS7680 Spice model                    **
**                      Revision RevA, 19 June 2009             **
******************************************************************
*Nom Temp 25 deg C
Dbody 7 5 DbodyMOD
Dbreak 5 11 DbreakMOD
Lgate 1 9 3.319e-9
Ldrain 2 5 0.004e-9
Lsource 3 7 0.844e-9
Rgate 9 6 0.98
* Shielded gate
D_D1         100 5 D_SG_cap
D_D2         100 101 D_SG_cap
R_R1         101 7  2.41
C_C1         6 101  168e-12
.MODEL D_SG_cap D (IS=1e-9 n=1 RS=4.0e-3 CJO=1.2e-9 M=0.6 t_abs=25)
It 7 17 1
Ebreak 11 7 17 7 33
Rbreak 17 7 RbreakMOD 1
.MODEL RbreakMOD RES (TC1=0.6e-3 TC2=-1e-6)
.MODEL DbodyMOD D (IS=1.0e-12 n=1 RS=3.2e-3 TRS1=1.5e-3 TRS2=1e-6
+ CJO=0.51e-9 M=0.35 TT=2e-9 XTI=1) ;CJO=1.02e-9
.MODEL DbreakMOD D (RS=30e-3 TRS1=1e-3 TRS2=1e-6 )
Rsource 7a 7 1.407e-3
Rdrain 5 16 RdrainMOD 3.15e-3
.MODEL RdrainMOD RES (TC1=4.5e-3 TC2=8e-6)
M_BSIM3 16 6 7a 7a Bsim3 W=2.81 L=1.57e-6 NRS=0 NRD=0
.MODEL Bsim3 NMOS (LEVEL=7 VERSION=3.1 MOBMOD=3 CAPMOD=2 paramchk=1 NQSMOD=0
*Process Parameters
+ TOX=500e-10 ;Oxide thickness
+ XJ=0.16e-6 ;Channel depth
+ NCH=1.9e17 ;Channel concentration
*Channel Current
+ U0=1000 VSAT=500000 DROUT=1.2
+ DELTA=0.15 PSCBE2=0.00001 RSH=1.407e-3
*Threshold voltage
+ VTH0=1.65
*Sub-threshold characteristics
+ VOFF=-0.1 NFACTOR=1.1
*Junction diodes and Capacitance
+ LINT=0.495e-6 DLC=0.495e-6
+ CGSO=60e-12 CGSL=10e-12 CGDO=1.5e-12 CGDL=115e-12 ;CGSO=120e-12
+ CJ=0 CF=0 CKAPPA=2.0
* Temperature parameters
+ KT1=-1.1 KT2=0 UA1=3e-9
+ NJ=10)
.ENDS FDMS7680