* PSpice Model Editor - Version 16.5.0
*$
.SUBCKT FDMS7678 2 1 3
******************************************************************
**      Fairchild Discrete Modeling Group                       **
******************************************************************
**      Website         www.fairchildsemi.com\models            **
******************************************************************
**      (C) Copyright 2009 Fairchild Semiconductor Corporation  **
**                      All rights reserved                     **
**                                                              **
**                      FDMS7678 Spice model                    **
**                      Revision RevA, 28 March 2012            **
******************************************************************		
*Nom Temp 25 deg C		
Dbody 7 5 DbodyMOD 		
Dbreak 5 11 DbreakMOD 		
Lgate 1 9 3.136e-9		
Ldrain 2 5 0.004e-9		
Lsource 3 7 0.823e-9		
RLgate 1 9 31.36		
RLdrain 2 5 0.04		
RLsource 3 7 8.23		
Rgate 9 6 0.86		
* Shielded  Gate  		
D_D1 100 5 D_SG_cap1		
D_D2 100 101 D_SG_cap2		
R_R1 101 7 1.84		
C_C1 6 101 205e-12		
.MODEL D_SG_cap1 D (IS=1e-9 n=1 RS=5e-3 CJO=2.57e-9 M=0.59 t_abs=25) 
.MODEL D_SG_cap2 D (IS=1e-9 n=1 RS=5e-3 CJO=1.15e-9 M=0.55 t_abs=25)		
It 7 17 1		
Ebreak 11 7 17 7 33		
Rbreak 17 7 RbreakMOD 1 		
.MODEL RbreakMOD RES (TC1=0.52e-3 TC2=-1e-6)		
.MODEL DbodyMOD D (IS=8.3e-12 n=1 RS=3.3e-3 TRS1=2e-3 TRS2=1e-6 		
+ CJO=0.44e-9 M=0.33 TT=3e-9 XTI=1.6) ;1.32		
.MODEL DbreakMOD D (RS=30e-3 TRS1=1e-3 TRS2=1e-6 )		
Rsource 7a 7 1.711e-3		
Rdrain 5 16 RdrainMOD 1.98e-3		
.MODEL RdrainMOD RES (TC1=5.4e-3 TC2=9e-6)		
M_BSIM3 16 6 7a 7a Bsim3 W=4.37 L=0.48e-6 NRS=0 NRD=0		
.MODEL Bsim3 NMOS (LEVEL=7 VERSION=3.1 MOBMOD=3 CAPMOD=2 paramchk=1 NQSMOD=0		
*Process Parameters		
+ TOX=500e-10 ;Oxide thickness		
+ XJ=0.195e-6 ;Channel depth		
+ NCH=1.24e17 ;Channel concentration		
*Channel Current		
+ U0=680 VSAT=500000 DROUT=1.2		
+ DELTA=0.2 PSCBE2=0 RSH=1.711e-3		
*Threshold voltage		
+ VTH0=1.62		
*Sub-threshold characteristics		
+ VOFF=-0.11 NFACTOR=1.1		
*Junction diodes and Capacitance		
+ LINT=0.09e-6 DLC=0.09e-6 		
+ CGSO=190e-12 CGSL=0 CGDO=4.5e-12 CGDL=160e-12 ;237		
+ CJ=0 CF=0 CKAPPA=0.65		
* Temperature parameters 		
+ KT1=-0.9 KT2=0 UA1=1.5e-9		
+ NJ=10)		
.ENDS   		
* 		
*$