.SUBCKT FDMS7670AS 2 1 3
******************************************************************
**      Fairchild Discrete Modeling Group                       **
******************************************************************
**      Website         www.fairchildsemi.com\models            **
**      Scott Pearson   scott.pearson@fairchildsemi.com         **
**      Chris Hanas     chris.hanas@fairchildsemi.com           **
******************************************************************
**      (C) Copyright 2009 Fairchild Semiconductor Corporation  **
**                      All rights reserved                     **
**                                                              **
**                      FDMS7670S Spice model                   **
**                      Revision RevA, 20 Aug 2009              **
**                      Part renamed to FDMS7670AS              **
******************************************************************
*Nom Temp 25 deg C
Dbody 7 5 DbodyMOD
Dschottky 7 5 DSchottkyMOD
Dbreak 5 11 DbreakMOD
Lgate 1 9 2.373e-9
Ldrain 2 5 0.004e-9
Lsource 3 7 0.525e-9
RLgate 1 9 23.73
RLdrain 2 5 0.04
RLsource 3 7 5.25
Rgate 9 6 0.76
* Shielded gate
D_D1         100 5 D_SG_cap
D_D2         100 101 D_SG_cap
R_R1         101 7  0.81
C_C1         6 101  656e-12
.MODEL D_SG_cap D (IS=1e-9 n=1 RS=4.0e-3 CJO=3.3e-9 M=0.6 t_abs=25)
It 7 17 1
Ebreak 11 7 17 7 33.5
Rbreak 17 7 RbreakMOD 1
.MODEL RbreakMOD RES (TC1=0.5e-3 TC2=-0.7e-6)
.MODEL DbodyMOD D (IS=2.5e-12 n=1 RS=1.5e-3 TRS1=1.5e-3 TRS2=1e-6
+ CJO=0.6e-9 M=0.3 TT=3e-9 XTI=1)
.MODEL DSchottkyMOD D (IS=3.349e-6 n=1 RS=45e-3 TRS1=1.5e-3 TRS2=1e-6
+ CJO=0.6e-9 M=0.3 TT=3e-9 XTI=-16)
.MODEL DbreakMOD D (RS=30e-3 TRS1=1e-3 TRS2=1e-6 )
Rsource 7a 7 0.83e-3
Rdrain 5 16 RdrainMOD 1.1e-3
.MODEL RdrainMOD RES (TC1=5.6e-3 TC2=12e-6)
M_BSIM3 16 6 7a 7a Bsim3 W=7.292 L=1.9e-6 NRS=0 NRD=0
.MODEL Bsim3 NMOS (LEVEL=7 VERSION=3.1 MOBMOD=3 CAPMOD=2 paramchk=1 NQSMOD=0
*Process Parameters
+ TOX=500e-10 ;Oxide thickness
+ XJ=0.16e-6 ;Channel depth
+ NCH=1.2e17 ;Channel concentration
*Channel Current
+ U0=750 VSAT=500000 DROUT=1.2
+ DELTA=0.28 PSCBE2=0.00001 RSH=0.83e-3
*Threshold voltage
+ VTH0=2.13
*Sub-threshold characteristics
+ VOFF=-0.2 NFACTOR=1.1
*Junction diodes and Capacitance
+ LINT=0.745e-6 DLC=0.745e-6
+ CGSO=90e-12 CGSL=0 CGDO=1e-12 CGDL=130e-12
+ CJ=0 CF=0 CKAPPA=1.5
* Temperature parameters
+ KT1=-1.1 KT2=0 UA1=3e-9
+ NJ=10)
.ENDS FDMS7670AS