* PSpice Model Editor - Version 16.0.0

*$
.SUBCKT FDMS7670 2 1 3
*Nom Temp 25 deg C
Dbody 7 5 DbodyMOD 
Dbreak 5 11 DbreakMOD 
Lgate 1 9 2.503e-9
Ldrain 2 5 0.004e-9
Lsource 3 7 0.432e-9
RLgate 1 9 25.03
RLdrain 2 5 0.04
RLsource 3 7 4.32
Rgate 9 6 1.23
It 7 17 1
Ebreak 11 7 17 7 33
Rbreak 17 7 RbreakMOD 1 
.MODEL RbreakMOD RES (TC1=7e-4 TC2=-1e-6)
.MODEL DbodyMOD D (IS=2.5e-12 n=1 RS=1.89e-3 TRS1=1.5e-3 TRS2=1e-6 
+ CJO=2.187e-9 M=0.32 TT=0.1e-9 XTI=3)
.MODEL DbreakMOD D (RS=30e-3 TRS1=1e-3 TRS2=1e-6 )
Rsource 7a 7 0.711e-3
Rdrain 5 16 RdrainMOD 1.7e-3 
.MODEL RdrainMOD RES (TC1=4.2e-3 TC2=1e-6)
M_BSIM3 16 6 7a 7a Bsim3 W=6.48 L=1.57e-6 NRS=0 NRD=0
.MODEL Bsim3 NMOS (LEVEL=7 VERSION=3.1 MOBMOD=3 CAPMOD=2 paramchk=1 NQSMOD=0
*Process Parameters
+ TOX=500e-10 ;Oxide thickness
+ XJ=0.16e-6 ;Channel depth
+ NCH=2.17e17 ;Channel concentration
*Channel Current
+ U0=1000 VSAT=5e5 DROUT=1.2
+ DELTA=0.12 PSCBE2=0.00001 RSH=0.711e-3
*Threshold voltage
+ VTH0=1.5
*Sub-threshold characteristics
+ VOFF=-0.1 NFACTOR=1.1
*Junction diodes and Capacitance
+ LINT=0.495e-6 DLC=0.495e-6
+ CGSO=89e-12 CGSL=10e-12 CGDO=1e-12 CGDL=105e-12
+ CJ=0 CF=0 CKAPPA=1
* Temperature parameters
+ KT1=-1.4 KT2=0 UA1=7e-9
+ NJ=10)
.ENDS
*FDMS7670(Rev.A) 12/10/2008
* ST
*$