.SUBCKT FDMS7658AS 2 1 3	
******************************************************************
**              Fairchild Discrete Modeling Group               **
******************************************************************
**      Website         www.fairchildsemi.com\models            **
**      Scott Pearson   scott.pearson@fairchildsemi.com         **
**      Chris Hanas     chris.hanas@fairchildsemi.com           **
******************************************************************
**      (C) Copyright 2009 Fairchild Semiconductor Corporation  **
**                      All rights reserved                     **
**                                                              **
**                      FDMS7658AS Spice model                  **
**                      Revision RevA, 09 Nov 2009              **
******************************************************************
	
*Nom Temp 25 deg C		

Dbody 		7 5 	DbodyMOD 		
Dschottky 	7 5 	DSchottkyMOD 		
Dbreak 		5 11 	DbreakMOD 		
Lgate 		1 9 	1.999e-9		
Ldrain 		2 5 	0.004e-9		
Lsource		3 7 	0.45e-9		
RLgate 		1 9 	19.99		
RLdrain 	2 5 	0.04		
RLsource 	3 7 	4.5		
Rgate 		9 6 	0.41	

*Shielded gate
D_D1       100 	5 	D_SG_cap
D_D2       100 	101 	D_SG_cap
R_R1       101 	7  	0.188
C_C1       6 	101  	30e-12
.MODEL D_SG_cap D (IS=1e-9 n=1 RS=4.0e-3 CJO=2e-9 M=0.53 t_abs=25)	

It 		7 	17 	1		
Ebreak 		11 	7 	17 	7 	35		
Rbreak 		17 	7 	RbreakMOD 	1 		

.MODEL RbreakMOD RES (TC1=1e-3 TC2=-1e-6)		

.MODEL DbodyMOD D (IS=5e-12 n=1 RS=1e-3 TRS1=1e-3 TRS2=1e-6 	
+ CJO=3.2e-9 M=0.35 TT=0.1e-9 XTI=1)		

.MODEL DSchottkyMOD D (IS=8e-6 n=1 RS=26e-3 TRS1=3.8e-3 TRS2=1e-6 	
+ CJO=.66e-9 M=0.35 TT=0.0013e-9 XTI=-20)		

.MODEL DbreakMOD D (RS=30e-3 TRS1=1e-3 TRS2=1e-6)		
Rsource 7a 7 0.18e-3		
Rdrain 5 16 RdrainMOD 1.1e-3	

.MODEL RdrainMOD RES (TC1=4e-3 TC2=14e-6)		

M_BSIM3 16 6 7a 7a Bsim3 W=13.21 L=2e-6 NRS=0 NRD=0
.MODEL Bsim3 NMOS (LEVEL=7 VERSION=3.1 MOBMOD=3 CAPMOD=2 paramchk=1 NQSMOD=0	

*Process Parameters		
+ TOX=450e-10 ;Oxide thickness		
+ XJ=0.16e-6 ;Channel depth		
+ NCH=1.2e17 ;Channel concentration		

*Channel Current		
+ U0=900 VSAT=50000 DROUT=1.2		
+ DELTA=.2 PSCBE2=0.00001 RSH=0.184e-3		

*Threshold voltage		
+ VTH0=2.22		

*Sub-threshold characteristics		
+ VOFF=-0.3 NFACTOR=1.1

*Junction diodes and Capacitance		
+ LINT=0.71e-6 DLC=0.71e-6 		
+ CGSO=30e-12 CGSL=0 CGDO=2.7e-12 CGDL=96e-12 		
+ CJ=0 CF=0 CKAPPA=2.2		

* Temperature parameters 		
+ KT1=-1 KT2=0 UA1=2e-9		
+ NJ=10)		

.ENDS