.SUBCKT FDMS7656AS 2 1 3
******************************************************************
**      Fairchild Discrete Modeling Group                       **
******************************************************************
**      Website         www.fairchildsemi.com\models            **
**      Scott Pearson   scott.pearson@fairchildsemi.com         **
**      Chris Hanas     chris.hanas@fairchildsemi.com           **
******************************************************************
**      (C) Copyright 2009 Fairchild Semiconductor Corporation  **
**                      All rights reserved                     **
**                                                              **
**                      FDMS7656AS Spice model                  **
**                      Revision RevA, 09 Nov 2009              **
******************************************************************
*Nom Temp 25 deg C
Dbody 7 5 DbodyMOD
Dschottky 7 5 DSchottkyMOD
Dbreak 5 11 DbreakMOD
Lgate 1 9 2.203e-9
Ldrain 2 5 0.004e-9
Lsource 3 7 0.387e-9
RLgate 1 9 22.03
RLdrain 2 5 0.04
RLsource 3 7 3.87
Rgate 9 6 0.38
*Shielded gate
D_D1       100     5     D_SG_cap
D_D2       100     101   D_SG_cap
R_R1       101     7     0.131
C_C1       6       101   278e-12
.MODEL D_SG_cap D (IS=1e-9 n=1 RS=4.0e-3 CJO=7.3e-9 M=0.53 t_abs=25)
It 7 17 1
Ebreak 11 7 17 7 33.2
Rbreak 17 7 RbreakMOD 1
.MODEL RbreakMOD RES (TC1=0.3e-3 TC2=-1e-6)
.MODEL DbodyMOD D (IS=8e-12 n=1 RS=0.9e-3 TRS1=2.3e-3 TRS2=1e-6
+ CJO=1.5e-9 M=0.44 TT=1e-9 XTI=1) ;4.5
.MODEL DSchottkyMOD D (IS=9.5e-6 n=1 RS=23e-3 TRS1=1.5e-3 TRS2=1e-6
+ CJO=1.5e-9 M=0.44 TT=1e-9 XTI=-19)
.MODEL DbreakMOD D (RS=30e-3 TRS1=1e-3 TRS2=1e-6 )
Rsource 7a 7 0.484e-3
Rdrain 5 16 RdrainMOD 0.67e-3
.MODEL RdrainMOD RES (TC1=5.6e-3 TC2=12.2e-6)
M_BSIM3 16 6 7a 7a Bsim3 W=14.137 L=2e-6 NRS=0 NRD=0
.MODEL Bsim3 NMOS (LEVEL=7 VERSION=3.1 MOBMOD=3 CAPMOD=2 paramchk=1 NQSMOD=0
*Process Parameters
+ TOX=450e-10 ;Oxide thickness
+ XJ=0.16e-6 ;Channel depth
+ NCH=2.2e17 ;Channel concentration
*Channel Current
+ U0=880 VSAT=500000 DROUT=1.2
+ DELTA=0.15 PSCBE2=0 RSH=0.484e-3
*Threshold voltage
+ VTH0=1.21
*Sub-threshold characteristics
+ VOFF=-0.1 NFACTOR=1.1
*Junction diodes and Capacitance
+ LINT=0.71e-6 DLC=0.71e-6
+ CGSO=49e-12 CGSL=0 CGDO=4e-12 CGDL=120e-12 ;65
+ CJ=0 CF=0 CKAPPA=1.2
* Temperature parameters
+ KT1=-1.1 KT2=0 UA1=0.7e-9
+ NJ=10)
.ENDS FDMS7656AS