.SUBCKT FDMS7602S_Q1 2 1 3
******************************************************************
**      Fairchild Discrete Modeling Group                       **
******************************************************************
**      Website         www.fairchildsemi.com\models            **
******************************************************************
**      (C) Copyright 2009 Fairchild Semiconductor Corporation  **
**                      All rights reserved                     **
**                                                              **
**                      FDMS7602S Spice model                   **
**                    Revision RevA, 08 Feb 2010                **
******************************************************************
*Nom Temp 25 deg C
Dbody 7 5 DbodyMOD 
Dbreak 5 11 DbreakMOD 
Lgate 1 9 2.137e-9
Ldrain 2 5 0.004e-9
Lsource 3 7 0.246e-9
RLgate 1 9 21.37
RLdrain 2 5 0.04
RLsource 3 7 2.46
Rgate 9 6 0.4
* Shielded  Gate
D1 100 5 D_SG_cap
D2 100 101 D_SG_cap
R1 101 7 0.724
C1 6 101 45e-12
.MODEL D_SG_cap D (IS=1e-9 n=1 RS=4e-3 CJO=1.7e-9 M=0.60 t_abs=25)
It 7 17 1
Ebreak 11 7 17 7 32.75
Rbreak 17 7 RbreakMOD 1 
.MODEL RbreakMOD RES (TC1=0.52e-3 TC2=-0.8e-6)
.MODEL DbodyMOD D (IS=1.5e-12 n=1 RS=4.5e-3 TRS1=0.3e-3 TRS2=0.5e-6 
+ CJO=0.33e-9 M=0.37 TT=0.1e-9 XTI=1)
.MODEL DbreakMOD D (RS=30e-3 TRS1=1e-3 TRS2=1e-6 )
Rsource 7a 7 0.674e-3
Rdrain 5 16 RdrainMOD 5e-3
.MODEL RdrainMOD RES (TC1=3.2e-3 TC2=10.2e-6)
M_BSIM3 16 6 7a 7a Bsim3 W=2.7 L=2e-6 NRS=0 NRD=0
.MODEL Bsim3 NMOS (LEVEL=7 VERSION=3.1 MOBMOD=3 CAPMOD=2 paramchk=1 NQSMOD=0
*Process Parameters
+ TOX=450e-10
+ XJ=0.16e-6
+ NCH=2.0e17
*Channel Current
+ U0=1200 VSAT=500000 DROUT=1.2
+ DELTA=0.35 PSCBE2=0 RSH=0.674e-3
*Threshold voltage
+ VTH0=1.7
*Sub-threshold characteristics
+ VOFF=-0.1 NFACTOR=1.1
*Junction diodes and Capacitance
+ LINT=0.71e-6 DLC=0.71e-6 
+ CGSO=60e-12 CGSL=0 CGDO=10e-12 CGDL=125.2e-12
+ CJ=0 CF=0 CKAPPA=0.18
* Temperature parameters 
+ KT1=-1.2 KT2=0 UA1=0.5e-9
+ NJ=10)
.ENDS

.SUBCKT FDMS7602S_Q2 2 1 3
*Nom Temp 25 deg C
Dbody 7 5 DbodyMOD 
Dschottky 7 5 DSchottkyMOD 
Dbreak 5 11 DbreakMOD 
Lgate 1 9 1.998e-9
Ldrain 2 5 0.004e-9
Lsource 3 7 0.379e-9
RLgate 1 9 19.98
RLdrain 2 5 0.04
RLsource 3 7 3.79
Rgate 9 6 1.22
* Shielded  Gate  
D_D1 100 5 D_SG_cap
D_D2 100 101 D_SG_cap
R1 101 7 0.64
C_C1 6 101 130e-12; 297e-12
.MODEL D_SG_cap D (IS=1e-9 n=1 RS=4e-3 CJO=3.1e-9 M=0.6 t_abs=25) 
It 7 17 1
Ebreak 11 7 17 7 33.4
Rbreak 17 7 RbreakMOD 1 
.MODEL RbreakMOD RES (TC1=0.48e-3 TC2=-1e-6)
.MODEL DbodyMOD D (IS=1.641e-12 n=1 RS=3.077e-3 TRS1=0.5e-3 TRS2=1e-6
+ CJO=0.267e-9 M=0.3 TT=0.1e-9 XTI=1.2); 
.MODEL DSchottkyMOD D (IS=3.063e-6 n=1 RS=60.067e-3 TRS1=1.5e-3 TRS2=10e-6; 
+ CJO=0.267e-9 M=0.3 TT=0.0013e-9 XTI=-18);
.MODEL DbreakMOD D (RS=30e-3 TRS1=1e-3 TRS2=1e-6)
Rsource 7a 7 1.547e-3
Rdrain 5 16 RdrainMOD 1.6e-3
.MODEL RdrainMOD RES (TC1=6e-3 TC2=11.2e-6)
M_BSIM3 16 6 7a 7a Bsim3 W=4.491 L=1.22e-6 NRS=0 NRD=0
.MODEL Bsim3 NMOS (LEVEL=7 VERSION=3.1 MOBMOD=3 CAPMOD=2 paramchk=1 NQSMOD=0
*Process Parameters
+ TOX=500e-10
+ XJ=0.16e-6
+ NCH=1.92e17
*Channel Current
+ U0=950 VSAT=500000 DROUT=1.2
+ DELTA=0.35 PSCBE2=0.00001 RSH=1.547e-3
*Threshold voltage
+ VTH0=1.31
*Sub-threshold characteristics
+ VOFF=-0.1 NFACTOR=1.1
*Junction diodes and Capacitance
+ LINT=0.375e-6 DLC=0.375e-6 
+ CGSO=112e-12 CGSL=10e-12 CGDO=10.5e-12 CGDL=200e-12;  
+ CJ=0 CF=0 CKAPPA=0.3
* Temperature parameters 
+ KT1=-1.1 KT2=0 UA1=0.1e-9
+ NJ=10)
.ENDS