.SUBCKT FDMS7558S 2 1 3
******************************************************************
**      Fairchild Discrete Modeling Group                       **
******************************************************************
**      Website         www.fairchildsemi.com\models            **
******************************************************************
**      (C) Copyright 2009 Fairchild Semiconductor Corporation  **
**                      All rights reserved                     **
**                                                              **
**                      FDMS7558S Spice model                   **
**                    Revision RevA, 9 Mar 2010                 **
******************************************************************
*Nom Temp 25 deg C
Dbody 7 5 DbodyMOD 
Dschottky 7 5 DSchottkyMOD 
Dbreak 5 11 DbreakMOD 
Lgate 1 9 0.853e-9
Ldrain 2 5 0.004e-9
Lsource 3 7 0.1e-9
RLgate 1 9 8.53
RLdrain 2 5 0.04
RLsource 3 7 1
Rgate 9 6 0.55
* Shielded  Gate  
D_D1 100 5 D_SG_cap
D_D2 100 101 D_SG_cap
R_R1 101 7 0.32
C_C1 6 101 394e-12
.MODEL D_SG_cap D (IS=1e-9 n=1 RS=4e-3 CJO=5.0e-9 M=0.6 t_abs=25) 
It 7 17 1
Ebreak 11 7 17 7 28.65
Rbreak 17 7 RbreakMOD 1 
.MODEL RbreakMOD RES (TC1=0.75e-3 TC2=-1e-6)
.MODEL DbodyMOD D (IS=6.5e-12 n=1 RS=0.759e-3 TRS1=1.5e-3 TRS2=1e-6 
+ CJO=0.63e-9 M=0.42 TT=3e-9 XTI=2.2)
.MODEL DSchottkyMOD D (IS=6.056e-6 n=1 RS=24.363e-3 TRS1=1.5e-3 TRS2=1e-6 
+ CJO=0.63e-9 M=0.42 TT=3e-9 XTI=-17)
.MODEL DbreakMOD D (RS=30e-3 TRS1=1e-3 TRS2=1e-6 )
Rsource 7a 7 0.171e-3
Rdrain 5 16 RdrainMOD 0.7e-3
.MODEL RdrainMOD RES (TC1=3.6e-3 TC2=8e-6)
M_BSIM3 16 6 7a 7a Bsim3 W=13.57 L=1.62e-6 NRS=0 NRD=0
.MODEL Bsim3 NMOS (LEVEL=7 VERSION=3.1 MOBMOD=3 CAPMOD=2 paramchk=1 NQSMOD=0
*Process Parameters
+ TOX=500e-10 ;Oxide thickness
+ XJ=0.16e-6 ;Channel depth
+ NCH=1.55e17 ;Channel concentration
*Channel Current
+ U0=870 VSAT=500000 DROUT=1.2
+ DELTA=0.3 PSCBE2=0.00001 RSH=0.171e-3
*Threshold voltage
+ VTH0=1.74
*Sub-threshold characteristics
+ VOFF=-0.3 NFACTOR=1.1
*Junction diodes and Capacitance
+ LINT=0.585e-6 DLC=0.585e-6 
+ CGSO=117.84e-12 CGSL=0 CGDO=19.8e-12 CGDL=110e-12 
+ CJ=0 CF=0 CKAPPA=0.3
* Temperature parameters 
+ KT1=-1.0 KT2=0 UA1=3e-9
+ NJ=10)
.ENDS