* OrCAD Model Editor - Version 9.1
*$
.SUBCKT FDMS6681Z 2 1 3   
*Nom Temp=25 deg C
Dbody 5 7 DbodyMOD
Dbreak 7 11 DbreakMOD
Ebreak 5 11 17 7 -33
Lgate 1 9 2.191e-9
Ldrain 2 5 0.004e-9 
Lsource 3 7 0.446e-9
RLgate 1 9 21.91
RLdrain 2 5 0.04
RLsource 3 7 4.46
Rgate 9 6 7
It 7 17 1
Rbreak 17 7 RbreakMOD 1
.MODEL RbreakMOD RES(TC1=0.7e-3 TC2=-0.4e-6)
.MODEL DbodyMOD D(IS=9.5e-12 n=1 RS=2.25e-3 TRS1=5e-5 TRS2=1e-6
+ CJO=1.34e-9 M=0.65 TT=18n XTI=3)
.MODEL DbreakMOD D(RS=100e-3 TRS1=1e-3 TRS2=1e-6)
Rsource 7a 7 0.533e-3
Rdrain 5 16 RdrainMOD 1.627e-3 
.MODEL RdrainMOD RES (TC1=4.5e-3 TC2=5e-6)
M_BSIM3 16 6 7a 7a Bsim3 W=19.04 L=1.1e-6 NRS=0 
.MODEL Bsim3 PMOS(LEVEL=7 VERSION=3.1 MOBMOD=3 CAPMOD=2 paramchk=1 NQSMOD=0)
**Process Parameters
+ TOX=550e-10 ;Oxide thickness
+ XJ=0.3e-6 ;Channel depth 
+ NCH=1.46e17 ;Channel concentration
**Channel Current
+ U0=220 vsat=5e5 drout=1.2 
+ DELTA=0.25 PSCBE2=0.00001 RSH=0.533e-3
**Threshold voltage
+ VTH0=-1.75
***Sub-threshold characteristics
+ VOFF=-0.16 NFACTOR=1
**Junction diodes and Capacitance
+ LINT=0.3e-6 DLC=0.3e-6 
+ CGSO=82e-12 CGSL=0e-12 CGDO=20e-12 CGDL=285e-12 
+ CJ=0 CF=0p CKAPPA=2
**Temperature parameters
+ KT1=-1.3 KT2=0 UA1=5.5e-9
+ NJ=10 
.ENDS 
*FDMS6681Z(Rev.A) 11/5/08
*ST
*$