.SUBCKT FDMS3668S_Q1 2 1 3
******************************************************************
**      Fairchild Discrete Modeling Group                       **
******************************************************************
**      Website www.fairchildsemi.com\models                    **
******************************************************************
**      (C) Copyright 2010 Fairchild Semiconductor Corporation  **
**                      All rights reserved                     **
**                                                              **
**                      FDMS3668S Spice model                   **
**                    Revision RevB, 27 October 2012         **
******************************************************************
*Nom Temp 25 deg C
Dbody 7 5 DbodyMOD
Dbreak 5 11 DbreakMOD
Lgate 1 9 2.037e-9
Ldrain 2 5 0.004e-9
Lsource 3 7 0.236e-9
RLgate 1 9 20.37
RLdrain 2 5 0.04
RLsource 3 7 2.36
Rgate 9 6 0.43

D_D1 100 5 D_SG_cap
D_D2 100 101 D_SG_cap
R_R1 101 7 1.33
C_C1 6 101 73e-12
.MODEL D_SG_cap D (IS=1e-9 n=1 RS=5e-3 CJO=1.17e-9 M=0.415 t_abs=25)
It 7 17 1
Ebreak 11 7 17 7 32.6
Rbreak 17 7 RbreakMOD 1
.MODEL RbreakMOD RES (TC1=0.6e-3 TC2=-0.85e-6)
.MODEL DbodyMOD D (IS=3.0e-12 n=1.05 RS=2.6e-3 TRS1=6e-3 TRS2=1e-6

+ CJO=0.35e-9 M=0.3 TT=3e-9 XTI=9)
.MODEL DbreakMOD D (RS=30e-3 TRS1=1e-3 TRS2=1e-6 )
Rsource 7a 7 0.797e-3
Rdrain 5 16 RdrainMOD 3.2e-3
.MODEL RdrainMOD RES (TC1=2.8e-3 TC2=6e-6)
M_BSIM3 16 6 7a 7a Bsim3 W=2.90934875 L=0.8e-6 NRS=0 NRD=0
.MODEL Bsim3 NMOS (LEVEL=7 VERSION=3.1 MOBMOD=3 CAPMOD=2 paramchk=1 NQSMOD=0

+ TOX=500e-10
+ XJ=0.16e-6
+ NCH=1.58e17
+ U0=825 VSAT=500000 DROUT=1.2
+ DELTA=0.18 PSCBE2=0 RSH=0.797e-3

+ VTH0=2.02
+ VOFF=-0.1 NFACTOR=1.4
+ LINT=0.135e-6 DLC=0.135e-6
+ CGSO=100e-12 CGSL=0 CGDO=1e-12 CGDL=180e-12
+ CJ=0 CF=0 CKAPPA=0.75

+ KT1=-1.55 KT2=0 UA1=10e-9
+ NJ=10)
.ENDS 

.SUBCKT FDMS3668S_Q2 2 1 3

******************************************************************
**      Fairchild Discrete Modeling Group                       **
******************************************************************
**      Website         www.fairchildsemi.com\models            **
******************************************************************
**      (C) Copyright 2009 Fairchild Semiconductor Corporation  **
**                      All rights reserved                     **
**                                                              **
**                      FDMS3668S_Q2 Spice model                **
**                      Revision RevB, 27 OCtober 2012              **
******************************************************************			
*Nom Temp 25 deg C		
Dbody 7 5 DbodyMOD 		
Dschottky 7 5 DSchottkyMOD 		
Dbreak 5 11 DbreakMOD 		
Lgate 1 9 0.853e-9		
Ldrain 2 5 0.004e-9		
Lsource 3 7 0.096e-9		
RLgate 1 9 8.53		
RLdrain 2 5 0.04		
RLsource 3 7 0.96		
Rgate 9 6 0.71		
	
D_D1 100 5 D_SG_cap		
D_D2 100 101 D_SG_cap		
R_R1 101 7 1.92		
C_C1 6 101 217e-12		
.MODEL D_SG_cap D (IS=1e-9 n=1 RS=2e-3 CJO=6.2e-9 M=0.6 t_abs=25) 		
It 7 17 1		
Ebreak 11 7 17 7 32.9		
Rbreak 17 7 RbreakMOD 1 		
.MODEL RbreakMOD RES (TC1=0.5e-3 TC2=-1e-6)		
.MODEL DbodyMOD D (IS=5e-12 n=1 RS=0.87e-3 TRS1=1e-3 TRS2=1e-6 		
+ CJO=0.74e-9 M=0.36 TT=3e-9 XTI=1.5)		
.MODEL DSchottkyMOD D (IS=4.7e-6 n=1 RS=37e-3 TRS1=1.5e-3 TRS2=1e-6 		
+ CJO=0.74e-9 M=0.36 TT=3e-9 XTI=-20)		
.MODEL DbreakMOD D (RS=30e-3 TRS1=1e-3 TRS2=1e-6 )		
Rsource 7a 7 0.162e-3		
Rdrain 5 16 RdrainMOD 1.22e-3		
.MODEL RdrainMOD RES (TC1=2.9e-3 TC2=12.2e-6)		
M_BSIM3 16 6 7a 7a Bsim3 W=10.35 L=1.7e-6 NRS=0 NRD=0		
.MODEL Bsim3 NMOS (LEVEL=7 VERSION=3.1 MOBMOD=3 CAPMOD=2 paramchk=1 NQSMOD=0		
	
+ TOX=500e-10 	
+ XJ=0.16e-6 		
+ NCH=1.57e17 
*Channel Current		
+ U0=890 VSAT=500000 DROUT=1.2		
+ DELTA=0.24 PSCBE2=0 RSH=0.162e-3		
	
+ VTH0=1.94		
	
+ VOFF=-0.22 NFACTOR=1.1		
	
+ LINT=0.595e-6 DLC=0.595e-6 		
+ CGSO=86e-12 CGSL=10e-12 CGDO=9e-12 CGDL=85e-12 ;107 		
+ CJ=0 CF=0 CKAPPA=0.25		

+ KT1=-1.1 KT2=0 UA1=3.3e-9		
+ NJ=10)		
.ENDS