* PSpice Model Editor - Version 16.3.0
*$
.SUBCKT FDMS3604S_Q1 2 1 3	
******************************************************************
**      Fairchild Discrete Modeling Group                       **
******************************************************************
**      Website         www.fairchildsemi.com\models            **
******************************************************************
**      (C) Copyright 2009 Fairchild Semiconductor Corporation  **
**                      All rights reserved                     **
**                                                              **
**                      FDMS3604S_Q1 Spice model                **
**                      Revision RevA, 15 October 2010          **
******************************************************************		
*Nom Temp 25 deg C		
Dbody 7 5 DbodyMOD 		
Dbreak 5 11 DbreakMOD 		
Lgate 1 9 2.924e-9		
Ldrain 2 5 0.004e-9		
Lsource 3 7 0.873e-9		
RLgate 1 9 29.24		
RLdrain 2 5 0.04		
RLsource 3 7 8.73		
Rgate 9 6 0.51		
* Shielded  Gate  		
D_D1 100 5 D_SG_cap		
D_D2 100 101 D_SG_cap		
R_R1 101 7 1.47		
C_C1 6 101 84e-12		
.MODEL D_SG_cap D (IS=1e-9 n=1 RS=1.5e-3 CJO=1.73e-9 M=0.6 t_abs=25) 		
It 7 17 1		
Ebreak 11 7 17 7 32.6		
Rbreak 17 7 RbreakMOD 1 		
.MODEL RbreakMOD RES (TC1=0.57e-3 TC2=-0.6e-6)		
.MODEL DbodyMOD D (IS=1.3e-12 n=1 RS=3.2e-3 TRS1=2.2e-3 TRS2=1e-6 		
+ CJO=0.33e-9 M=0.3 TT=3e-9 XTI=5) ;1.0		
.MODEL DbreakMOD D (RS=30e-3 TRS1=1e-3 TRS2=1e-6 )		
Rsource 7a 7 1.723e-3		
Rdrain 5 16 RdrainMOD 2.18e-3		
.MODEL RdrainMOD RES (TC1=5.3e-3 TC2=13e-6)		
M_BSIM3 16 6 7a 7a Bsim3 W=3.09 L=1.7e-6 NRS=0 NRD=0		
.MODEL Bsim3 NMOS (LEVEL=7 VERSION=3.1 MOBMOD=3 CAPMOD=2 paramchk=1 NQSMOD=0		
*Process Parameters		
+ TOX=500e-10 ;Oxide thickness		
+ XJ=0.16e-6 ;Channel depth		
+ NCH=1.55e17 ;Channel concentration		
*Channel Current		
+ U0=1000 VSAT=500000 DROUT=1.2		
+ DELTA=0.28 PSCBE2=0 RSH=1.723e-3		
*Threshold voltage		
+ VTH0=2.15		
*Sub-threshold characteristics		
+ VOFF=-0.16 NFACTOR=1.5		
*Junction diodes and Capacitance		
+ LINT=0.585e-6 DLC=0.585e-6 		
+ CGSO=109e-12 CGSL=10e-12 CGDO=11e-12 CGDL=140e-12 ;136 		
+ CJ=0 CF=0 CKAPPA=0.25		
* Temperature parameters 		
+ KT1=-1.12 KT2=0 UA1=2.5e-9		
+ NJ=10)		
.ENDS
*$
.SUBCKT FDMS3604S_Q2 2 1 3
******************************************************************
**      Fairchild Discrete Modeling Group                       **
******************************************************************
**      Website         www.fairchildsemi.com\models            **
******************************************************************
**      (C) Copyright 2009 Fairchild Semiconductor Corporation  **
**                      All rights reserved                     **
**                                                              **
**                      FDMS3604S_Q2 Spice model                **
**                      Revision RevA, 14 Oct 2010              **
******************************************************************		
*Nom Temp 25 deg C		
Dbody 7 5 DbodyMOD 		
Dschottky 7 5 DSchottkyMOD 		
Dbreak 5 11 DbreakMOD 		
Lgate 1 9 0.853e-9		
Ldrain 2 5 0.004e-9		
Lsource 3 7 0.177e-9		
RLgate 1 9 8.53		
RLdrain 2 5 0.04		
RLsource 3 7 1.77		
Rgate 9 6 0.92		
* Shielded  Gate  		
D_D1 100 5 D_SG_cap		
D_D2 100 101 D_SG_cap		
R_R1 101 7 2.54		
C_C1 6 101 160e-12		
.MODEL D_SG_cap D (IS=1e-9 n=1 RS=2.6e-3 CJO=4.5e-9 M=0.6 t_abs=25) 		
It 7 17 1		
Ebreak 11 7 17 7 33.3		
Rbreak 17 7 RbreakMOD 1 		
.MODEL RbreakMOD RES (TC1=0.48e-3 TC2=-1e-6)		
.MODEL DbodyMOD D (IS=2.6e-12 n=1 RS=1.1e-3 TRS1=1e-3 TRS2=1e-6 		
+ CJO=0.47e-9 M=0.33 TT=3e-9 XTI=1.5) ;1.4		
.MODEL DSchottkyMOD D (IS=3.7e-6 n=1 RS=47e-3 TRS1=1.5e-3 TRS2=1e-6 		
+ CJO=0.47e-9 M=0.33 TT=3e-9 XTI=-20)		
.MODEL DbreakMOD D (RS=30e-3 TRS1=1e-3 TRS2=1e-6 )		
Rsource 7a 7 0.208e-3		
Rdrain 5 16 RdrainMOD 1.3e-3		
.MODEL RdrainMOD RES (TC1=3e-3 TC2=10.3e-6)		
M_BSIM3 16 6 7a 7a Bsim3 W=7.61 L=1.7e-6 NRS=0 NRD=0		
.MODEL Bsim3 NMOS (LEVEL=7 VERSION=3.1 MOBMOD=3 CAPMOD=2 paramchk=1 NQSMOD=0		
*Process Parameters		
+ TOX=500e-10 ;Oxide thickness		
+ XJ=0.16e-6 ;Channel depth		
+ NCH=1.58e17 ;Channel concentration		
*Channel Current		
+ U0=760 VSAT=500000 DROUT=1.2		
+ DELTA=0.12 PSCBE2=0 RSH=0.208e-3		
*Threshold voltage		
+ VTH0=1.9		
*Sub-threshold characteristics		
+ VOFF=-0.15 NFACTOR=1.1		
*Junction diodes and Capacitance		
+ LINT=0.595e-6 DLC=0.595e-6 		
+ CGSO=85e-12 CGSL=10e-12 CGDO=10e-12 CGDL=115e-12 ;106		
+ CJ=0 CF=0 CKAPPA=0.25		
* Temperature parameters 		
+ KT1=-1.1 KT2=0 UA1=2.8e-9		
+ NJ=10)		
.ENDS   		
*$