* PSpice Model Editor - Version 10.5.0
*$
.SUBCKT FDMS3500 2 1 3    
*Nom Temp=25 deg C
Dbody 7 5 DbodyMOD
Dbreak 5 11 DbreakMOD
Lgate 1 9 2.337e-9
Ldrain 2 5 0.004e-9
Lsource 3 7 0.384e-9
RLgate 1 9 23.37
RLdrain 2 5 0.04
RLsource 3 7 3.84
Rgate 9 6 1.08
It 7 17 1
Ebreak 11 7 17 7 82
Rbreak 17 7 RbreakMOD 1
.MODEL RbreakMOD RES (TC1=0.93e-3 TC2=-1e-6)
.MODEL DbodyMOD D (IS=3.525e-12 n=1 RS=1.56e-3 TRS1=1.1e-3 TRS2=1e-6
+ CJO=1.25e-9 M=0.58 TT=0e-9 XTI=0.1)
.MODEL DbreakMOD D (RS=100e-3 TRS1=1e-3 TRS2=1e-6)
Rdrain 5 16 RdrainMOD 8.13e-3
.MODEL RdrainMOD RES (TC1=4e-3 TC2=1e-6)
M_BSIM3 16 6 7 7 Bsim3 W=5.48 L=1.58e-6 NRS=0 NRD=0
.MODEL Bsim3 NMOS(LEVEL=7 VERSION=3.1 MOBMOD=3 CAPMOD=2 paramchk=1 NQSMOD=0)
**Process Parameters
+ TOX=500e-10 ;Oxide thickness
+ XJ=0.915e-6 ;Channel depth
+ NCH=1.2e17 ;Channel concentration
**Channel Current
+ U0=700 VSAT=5e5 DROUT=1.5
+ DELTA=0.1 PSCBE2=1e-5 RSH=0.804e-3   
**Threshold voltage
+ VTH0=2
**Sub-threshold characteristics
+ VOFF=-.1 NFACTOR=1.1
**Junction diodes and Capacitance
+ LINT=0.305e-6 DLC=0.305e-6 
+ CGSO=191p CGSL=0 CGDO=8p CGDL=187p
+ CJ=0 CF=0 CKAPPA=2.5
** Temperature parameters
+ KT1=-1.15 KT2=0 UA1=2.5e-9
+ NJ=10)
.ENDS
*FDMS3500(Rev.A) 4/4/2008
*ST
*$