* OrCAD Model Editor - Version 9.1
*$
.SUBCKT FDMS2572 2 1 3 
*Nom Temp=25 deg C
Dbody 7 5 DbodyMOD
Dbreak 5 11 DbreakMOD
Ebreak 11 7 17 7 160
Lgate 1 9 2e-9
Ldrain 2 5 1.0e-10
Lsource 3 7 1.2e-10
RLgate 1 9 20
RLdrain 2 5 1
RLsource 3 7 1.2
Rgate 9 6 1.3
It 7 17 1
Rbreak 17 7 RbreakMOD 1 
.MODEL RbreakMOD RES (TC1=8.5e-4 TC2=-4e-7)
.MODEL DbodyMOD D (IS=3.08e-12 n=1.01 RS=4.2m TRS1=1.2e-3 TRS2=1e-9
+ CJO=1.35e-9 M=0.55 TT=87n XTI=1)
.MODEL DbreakMOD D (RS=0.3 TRS1=1e-3 TRS2=1e-6)
M_BSIM3 16 6 7 7 M_MOD W=3.24 L=1.85u NRS=1 
Rdrain 5 16 RdrainMOD 32m
.MODEL RdrainMOD RES (TC1=5.5e-3 TC2=1.6e-5)
.MODEL  M_MOD NMOS (LEVEL=7 VERSION=3.2 MOBMOD=3 CAPMOD=3 paramchk=1 NQSMOD=0
***Process Parameters
+ TOX=1080e-10 ;Oxide thickness
+ XJ=1.55u ;Channel depth
+ NCH=1.6e17 ;Channel concentration
***Channel Current
+ U0=1500 VSAT=1e5 DROUT=2
+ PSCBE2=0 DELTA=0.2 RSH=1.75m 
***Threshold voltage
+ VTH0=2.68
***Sub-threshold characteristics
+ VOFF=-0.09 NFACTOR=1.8
***Junction diodes and Capacitance
+ LINT=0.275u DLC=0.275u
+ CGSO=200p CGSL=0p CGDO=10p CGDL=170p
+ CF=0p CJ=0 CKAPPA=0.6
*** Temperature parameters
+ KT1=-1.2 KT2=0 UA1=2e-9
+ NJ=10
.ENDS 
*FDD5810 (Rev.A) 4/21/06
*ST
*$