.SUBCKT FDMS037N08B 2 1 3
******************************************************************
**      Fairchild Discrete Modeling Group                       **
******************************************************************
**      Website         www.fairchildsemi.com\models            **
******************************************************************
**      (C) Copyright 2012 Fairchild Semiconductor Corporation  **
**                      All rights reserved                     **
**                                                              **
**                      FDMS037N08B Spice model                	**
**                    Revision RevA, 06 Dec 2012                **
******************************************************************
*Nom Temp 25 deg C
Dbody 7 5 DbodyMOD 
Dbreak 5 11 DbreakMOD 
Lgate 1 9 1.808e-9
Ldrain 2 5 0.004e-9
Lsource 3 7 0.318e-9
RLgate 1 9 18.08
RLdrain 2 5 0.04
RLsource 3 7 3.18
Rgate 9 6 0.49
*
D_D1 100 5 D_SG_cap
D_D2 100 101 D_SG_cap
R_R1 101 7 1.29
C_C1 6 101 715e-12
.MODEL D_SG_cap D (IS=1e-9 n=1 RS=4e-3 CJO=3.53e-9 M=0.41 t_abs=25) 
*
It 7 17 1
Ebreak 11 7 17 7 84.1
Rbreak 17 7 RbreakMOD 1 
.MODEL RbreakMOD RES (TC1=0.61e-3 TC2=-0.8e-6)
.MODEL DbodyMOD D (IS=1e-12 n=1 RS=1.25e-3 TRS1=1.7e-3 TRS2=1e-6 
+ CJO=0.9e-9 M=0.28 TT=3e-9 XTI=1)
.MODEL DbreakMOD D (RS=30e-3 TRS1=1e-3 TRS2=1e-6 )
Rsource 7a 7 0.376e-3
Rdrain 5 16 RdrainMOD 2.085e-3
.MODEL RdrainMOD RES (TC1=6.1e-3 TC2=16e-6)
M_BSIM3 16 6 7a 7a Bsim3 W=8.59047619047619 L=0.96e-6 NRS=0 NRD=0
.MODEL Bsim3 NMOS (LEVEL=7 VERSION=3.1 MOBMOD=3 CAPMOD=2 paramchk=1 NQSMOD=0
*
+ TOX=1000e-10 
+ XJ=0.28e-6 
+ NCH=1.93e17 
*
+ U0=1370 VSAT=500000 DROUT=1.2
+ DELTA=0.4 PSCBE2=0 RSH=0.376e-3
*
+ VTH0=2.27
*
+ VOFF=-0.1 NFACTOR=1
*
+ LINT=0.16e-6 DLC=0.16e-6 
+ CGSO=332e-12 CGSL=0 CGDO=0.1e-12 CGDL=162e-12 
+ CJ=0 CF=0 CKAPPA=1
*
+ KT1=-1.4 KT2=0 UA1=-5e-9
+ NJ=10)
.ENDS   
*