.SUBCKT FDMS0312S 2 1 3
******************************************************************
**      Fairchild Discrete Modeling Group                       **
******************************************************************
**      Website         www.fairchildsemi.com\models            **
******************************************************************
**      (C) Copyright 2009 Fairchild Semiconductor Corporation  **
**                      All rights reserved                     **
**                                                              **
**                      FDMS0312S Spice model                   **
**                      Revision RevA, 26 Jan 2010              **
**                      Revision RevA1, 27 Jun 2011             **
******************************************************************
*Nom Temp 25 deg C
Dbody 7 5 DbodyMOD
Dschottky 7 5 DSchottkyMOD
Dbreak 5 11 DbreakMOD
Lgate 1 9 2.994e-9
Ldrain 2 5 0.004e-9
Lsource 3 7 0.526e-9
RLgate 1 9 29.94
RLdrain 2 5 0.04
RLsource 3 7 5.26
Rgate 9 6 0.6
* Shielded  Gate
D_D1 100 5 D_SG_cap
D_D2 100 101 D_SG_cap
R_R1 101 7 0.26
C_C1 6 101 110e-12
.MODEL D_SG_cap D (IS=1e-9 n=1 RS=4e-3 CJO=2.52e-9 M=0.6 t_abs=25)
It 7 17 1
Ebreak 11 7 17 7 33
Rbreak 17 7 RbreakMOD 1
.MODEL RbreakMOD RES (TC1=0.4e-3 TC2=-1e-6)
.MODEL DbodyMOD D (IS=2e-12 n=1 RS=3.3e-3 TRS1=0.1e-4 TRS2=1e-6
+ CJO=0.67e-9 M=0.68 TT=3e-9 XTI=1) ;CJO=2e-9
.MODEL DSchottkyMOD D (IS=2e-6 n=1 RS=60e-3 TRS1=1.5e-3 TRS2=1e-6
+ CJO=0.67e-9 M=0.68 TT=3e-9 XTI=-16) ;CJO=2e-9
.MODEL DbreakMOD D (RS=30e-3 TRS1=1e-3 TRS2=1e-6 )
Rsource 7a 7 1.557e-3
Rdrain 5 16 RdrainMOD 1.3e-3
.MODEL RdrainMOD RES (TC1=8e-3 TC2=7.2e-6)
M_BSIM3 16 6 7a 7a Bsim3 W=5.01 L=1.22e-6 NRS=0 NRD=0
.MODEL Bsim3 NMOS (LEVEL=7 VERSION=3.1 MOBMOD=3 CAPMOD=2 paramchk=1 NQSMOD=0
*Process Parameters
+ TOX=500e-10 ;Oxide thickness
+ XJ=0.16e-6 ;Channel depth
+ NCH=2.2e17 ;Channel concentration
*Channel Current
+ U0=1175 VSAT=500000 DROUT=1.2
+ DELTA=0.32 PSCBE2=0 RSH=1.557e-3
*Threshold voltage
+ VTH0=1.28
*Sub-threshold characteristics
+ VOFF=-0.1 NFACTOR=1.2
*Junction diodes and Capacitance
+ LINT=0.375e-6 DLC=0.375e-6
+ CGSO=88e-12 CGSL=10e-12 CGDO=12e-12 CGDL=135e-12 ;CGSO=110e-12
+ CJ=0 CF=0 CKAPPA=0.21
* CJ=0 CF=0 CKAPPA=0.25
* Temperature parameters
+ KT1=-1.1 KT2=0 UA1=1e-10
+ NJ=10)
.ENDS