.SUBCKT FDMS030N06B 2 1 3
******************************************************************
**              Fairchild Discrete Modeling Group               **
******************************************************************
**                 Website www.fairchildsemi.com                **
******************************************************************
**     (C) Copyright 2013 Fairchild Semiconductor Corporation   **
**                      All rights reserved                     **
**                                                              **
**                      FDMS030N06B Spice model                 **
**                    Revision RevA, 18 Jan 2013                **
******************************************************************
*Nom Temp 25 deg C
Dbody 7 5 DbodyMOD 
Dbreak 5 11 DbreakMOD 
Lgate 1 9 1.883e-9
Ldrain 2 5 0.004e-9
Lsource 3 7 0.329e-9
RLgate 1 9 18.83
RLdrain 2 5 0.04
RLsource 3 7 3.29
Rgate 9 6 0.89
D_D1 100 5 D_SG_cap
D_D2 100 101 D_SG_cap
R_R1 101 7 0.527
C_C1 6 101 650e-12
.MODEL D_SG_cap D (IS=1e-9 n=1 RS=5e-3 CJO=5.45e-9 M=0.41 t_abs=25) 
It 7 17 1
Ebreak 11 7 17 7 67.2
Rbreak 17 7 RbreakMOD 1 
.MODEL RbreakMOD RES (TC1=0.5e-3 TC2=-0.45e-6)
.MODEL DbodyMOD D (IS=2.5e-12 n=1 RS=1.18e-3 TRS1=3e-3 TRS2=1e-6 
+ CJO=1.42e-9 M=0.26 TT=3e-9 XTI=3.75)
.MODEL DbreakMOD D (RS=30e-3 TRS1=1e-3 TRS2=1e-6 )
Rsource 7a 7 0.405e-3
Rdrain 5 16 RdrainMOD 1.5e-3
.MODEL RdrainMOD RES (TC1=5.6e-3 TC2=14.5e-6)
M_BSIM3 16 6 7a 7a Bsim3 W=10.95 L=0.85e-6 NRS=0 NRD=0
.MODEL Bsim3 NMOS (LEVEL=7 VERSION=3.1 MOBMOD=3 CAPMOD=2 paramchk=1 NQSMOD=0
+ TOX=1000e-10 
+ XJ=0.26e-6 
+ NCH=1.47e17 
+ U0=1125 VSAT=500000 DROUT=1.2
+ DELTA=0.4 PSCBE2=0 RSH=0.405e-3
+ VTH0=3.3
+ VOFF=-0.1 NFACTOR=0.9
+ LINT=0.085e-6 DLC=0.085e-6 
+ CGSO=240e-12 CGSL=0 CGDO=0.2e-12 CGDL=124e-12 
+ CJ=0 CF=0 CKAPPA=0.75
+ KT1=-1.9 KT2=0 UA1=1e-9
+ NJ=10)
.ENDS   
*