.SUBCKT FDMS0309AS 2 1 3
******************************************************************
**      Fairchild Discrete Modeling Group                       **
******************************************************************
**      Website         www.fairchildsemi.com\models            **
******************************************************************
**      (C) Copyright 2009 Fairchild Semiconductor Corporation  **
**                      All rights reserved                     **
**                                                              **
**                      FDMS0309AS Spice model                  **
**                    Revision RevA, 29 Mar 2011                **
******************************************************************
*Nom Temp 25 deg C
Dbody 7 5 DbodyMOD 
Dschottky 7 5 DSchottkyMOD 
Dbreak 5 11 DbreakMOD 
Lgate 1 9 2.964e-9
Ldrain 2 5 0.004e-9
Lsource 3 7 0.641e-9
RLgate 1 9 29.64
RLdrain 2 5 0.04
RLsource 3 7 6.41
Rgate 9 6 0.5
*
* Shielded  Gate  
D_D1 100 5 D_SG_cap
D_D2 100 101 D_SG_cap
R_R1 101 7 0.36
C_C1 6 101 226e-12
.MODEL D_SG_cap D (IS=1e-9 n=1 RS=5e-3 CJO=2.275e-9 M=0.51 t_abs=25) 
*
It 7 17 1
Ebreak 11 7 17 7 31.7
Rbreak 17 7 RbreakMOD 1 
.MODEL RbreakMOD RES (TC1=0.8e-3 TC2=-1e-6)
.MODEL DbodyMOD D (IS=8e-12 n=1.025 RS=2.04e-3 TRS1=1.5e-3 TRS2=1e-6 
+ CJO=0.29e-9 M=0.345 TT=3e-9 XTI=1.75)
.MODEL DSchottkyMOD D (IS=5e-6 n=1.15 RS=100e-3 TRS1=2.7e-3 TRS2=1e-6 
+ CJO=0.29e-9 M=0.345 TT=3e-9 XTI=-16.5)
.MODEL DbreakMOD D (RS=30e-3 TRS1=1e-3 TRS2=1e-6 )
*
Rsource 7a 7 0.546e-3
Rdrain 5 16 RdrainMOD 1.77e-3
.MODEL RdrainMOD RES (TC1=3.35e-3 TC2=4e-6)
*
M_BSIM3 16 6 7a 7a Bsim3 W=5.2525 L=0.624e-6 NRS=0 NRD=0
.MODEL Bsim3 NMOS (LEVEL=7 VERSION=3.1 MOBMOD=3 CAPMOD=2 paramchk=1 NQSMOD=0
*Process Parameters
+ TOX=500e-10 ;Oxide thickness
+ XJ=0.195e-6 ;Channel depth
+ NCH=1.38e17 ;Channel concentration
*Channel Current
+ U0=670 VSAT=500000 DROUT=1.2
+ DELTA=0.2 PSCBE2=0 RSH=0.546e-3
*Threshold voltage
+ VTH0=1.78
*Sub-threshold characteristics
+ VOFF=-0.13 NFACTOR=1.5
*Junction diodes and Capacitance
+ LINT=0.1445e-6 DLC=0.1445e-6 
+ CGSO=176e-12 CGSL=0 CGDO=5.6e-12 CGDL=175e-12 
+ CJ=0 CF=0 CKAPPA=0.6
* Temperature parameters 
+ KT1=-1.1 KT2=0 UA1=7e-9
+ NJ=10)
.ENDS