*
.SUBCKT FDME820NZT 2 1 3
******************************************************************
**      Fairchild Discrete Modeling Group                       **
******************************************************************
**      Website         www.fairchildsemi.com\models            **
******************************************************************
**      (C) Copyright 2011 Fairchild Semiconductor Corporation  **
**                      All rights reserved                     **
**                                                              **
**                      FDME820NZT Spice model                  **
**                    Revision RevA, 07 Nov 2011                **
**       Revision RevB, 12/12/2018 added gate zener diode       **
******************************************************************
*Nom Temp 25 deg C
Dbody 7 5 DbodyMOD 
Dbreak 5 11 DbreakMOD 
Desd1 91 9 DesdMOD
Desd2 91 7 DesdMOD
Lgate 1 9 0.85e-9
Ldrain 2 5 0.007e-9
Lsource 3 7 0.261e-9
RLgate 1 9 8.5
RLdrain 2 5 0.07
RLsource 3 7 2.61
Rgate 9 6 2.69
D_D1 100 5 D_SG_cap
D_D2 100 101 D_SG_cap
R_R1 101 6 1.01
C_C1 101 7 64e-12
.MODEL D_SG_cap D (IS=1e-9 n=1 RS=4e-3 CJO=0.01e-9 M=0.62 t_abs=25)
It 7 17 1
Ebreak 11 7 17 7 26.6
Rbreak 17 7 RbreakMOD 1 
.MODEL RbreakMOD RES (TC1=0.73e-3 TC2=-0.5e-6)
.MODEL DbodyMOD D (IS=6.25e-12 n=1 RS=14.25e-3 TRS1=3e-3 TRS2=1e-6 
+ CJO=0.003e-9 M=0.9 TT=3e-9 XTI=1)
.MODEL DbreakMOD D (RS=30e-3 TRS1=1e-3 TRS2=1e-6 )
.MODEL DesdMOD D(is=1430e-9 xti=9 Bv=13.4 tbv1=-0.04e-3 n=7.6 Rs=12 trs1=-7e-3)
Rsource 77 7 7.016e-3
Rdrain 5 16 RdrainMOD 4.85e-3
.MODEL RdrainMOD RES (TC1=7.75e-3 TC2=7e-6)
M_BSIM3 16 6 77 77 Bsim3 W=1.17725 L=0.57e-6 NRS=0 NRD=0
.MODEL Bsim3 NMOS (LEVEL=7 VERSION=3.1 MOBMOD=3 CAPMOD=2 paramchk=1 NQSMOD=0
+ TOX=240e-10
+ XJ=0.13e-6
+ NCH=2.1e17
+ U0=750 VSAT=500000 DROUT=1.2
+ DELTA=0.3 PSCBE2=0 RSH=7.016e-3
+ VTH0=0.44
+ VOFF=-0.1 NFACTOR=0.9
+ LINT=0.14e-6 DLC=0.14e-6 
+ CGSO=232e-12 CGSL=0 CGDO=135e-12 CGDL=400e-12 
+ CJ=0 CF=0 CKAPPA=0.8
* Temperature parameters 
+ KT1=-0.58 KT2=0 UA1=6e-9
+ NJ=10)
.ENDS   
*